*COMDECK PBLN06 
         NAM   PBLN06             INTERRUPT HANDLER - LINE 06 
*CALL SYSPGMAC
         ENT   PBLN06 
         ENT   HIPAGE 
         EXT   JKMASK             SOFTWARE PRIORITY MASKS 
         EXT   LEVELNO            SOFTWARE PRIORITY LEVEL 
         EXT     PTHIPINT     COUPLER INTERRUPT HANDLER 
          EXT    ACPLR1      COUPLER LINE NUMBER 1
          EXT    ACPLR2      COUPLER LINE NUMBER 2
         EQU   PRILVL(7)          COUPLER SOFTWARE PRIORITY LEVEL 
         EQU   MASK(PRILVL-1) 
         SPC   2
PBLN06    NOP 
          SRG    SAVE              SAVE REGISTERS 
ALEVNO   LDA   LEVELNO
         STA*  AREA               SAVE SOFTWARE PRIORITY LEVEL
         ENA   PRILVL 
         STA*  (ALEVNO+1)         STORE COUPLER PRIORITY LEVEL
         LDQ   =XJKMASK 
         LDA-  MASK,Q 
         LAM   M         AND MASK 
         EIN   0
          SAVPGE PGSAVE,*    SAVE CURRENT PAGE
          SETPGE HIPAGE,*    SWITCH TO HIPS PAGE
          LDQ*   PBLN06            GET RETURN-ADDR (117 OR 11B) 
          ADQ    =N-$117
          SQZ    CPLRTWO           INTERRUPT FROM COUPLER TWO PORT 5
CPLRONE   RTJ    PTHIPINT          CALL HIP-INT-ROUT FOR COUPLER ONE
          ADC    ACPLR1      COUPLER LINE NUMBER 1
          JMP*   CPLR 
CPLRTWO   RAO*   (ALEVNO+1)  BUMP SOFTWARE PRIORITY LEVEL  FOR COUPL-2
          RTJ*   (CPLRONE+1) CALL HIP-INT-ROUT FOR COUPLER TWO
          ADC    ACPLR2      COUPLER LINE NUMBER 2
CPLR      EQU    CPLR(*)
          SETPGE PGSAVE,*    RESTORE CURRENT PAGE 
         IIN   0
         LDA*  AREA 
         STA*  (ALEVNO+1)         RESTORE SOFTWARE PRIORITY LEVEL 
         LRG   SAVE               RESTORE REGISTERS,OVERFLOW
          JMP*   (PBLN06)          EXIT FROM COUPLER-INTERRUPT
AREA     BZS   AREA(10) 
SAVE     ADC   AREA-10
HIPAGE   NUM   0         HIP PAGE NUMBER (SUPPLIED BY MPEDIT) 
PGSAVE   NUM   0         PAGE SAVE AREA 
         END
