*COMDECK PBGETPAGE
******************************
*                            *
*         PBGETPAGE          *
*    READ PAGE REGISTER      *
*                            *
******************************
*              NON-RECURSIVE
*              NON-INTERRUPTABLE
************************************************************************
*                                                                      *
**OVERVIEW- PBGETPAGE READS A SPECIFIED PAGE REGISTER FROM             *
*           EITHER PAGE REGISTER BANK.                                 *
*                                                                      *
**INPUT- THE FIRST PARAMETER CONTAINS THE PAGE REGISTER TO READ        *
*        (0-31) AND THE PAGE REGISTER BANK TO USE (LEFTMOST BIT        *
*        SET MEANS BANK 1, NOT SET MEANS BANK 0).  THE SECOND          *
*        PARAMETER IS USED TO RETURN THE VALUE READ.                   *
*                                                                      *
**OUTPUT- CONTENTS OF SPECIFIED PAGE REGISTER RETURNED.                *
*                                                                      *
**EXTERNAL SUBROUTINES- NONE                                           *
*                                                                      *
************************************************************************
         NAM   PBGETPAGE
         ENT   PBGETPAGE
         EXT   QTOPSK 
* 
PBGETP   NOP   0
         IIN   0         INHIBIT INTERRUPTS 
         LDQ*  (PBGETP) 
         LDA   0,Q       GET PAGE REGISTER AND BANK 
         ALS   11        MOVE TO UPPER 5 BITS 
         RPR   A         READ PAGE REGISTER 
         RAO*  PBGETP    BUMP PAST PARAMETER
         LDQ*  (PBGETP)  GET ADDRESS FOR RESULT 
         STA   0,Q       STORE PAGE CONTENTS
         RAO*  PBGETP    BUMP PAST PARAMETER
         LDQ   QTOPSK    CHECK INTERRUPT COUNT
         SQN   1
         EIN   0         ENABLE INTERRUPTS
         JMP*  (PBGETP) 
         END
