*COMDECK PBFILE 
         NAM   PBFILE1   DISPLAY/LOAD FILE1(I)
         ENT   PBEF      LOAD FILE1(I)
PBEF     NOP   0
         SR3*  R3SVE     SAVE R3
         LDQ*  (PBEF) 
         LDA   0,Q
         SAN   3
         LDQ   =N$FF     LOAD ALL 256 FILE 1 REGISTERS
         JMP*  PBEF1
         LDQ   0,Q       GET FILE1 INDEX AND NO. WORDS
         INA   -1        DECREMENT INDEX BY 1 
         ALS   8
         QRS   8
         LLS   8
PBEF1    RAO*  PBEF 
         LDA*  (PBEF)    GET LOAD ADDRESS 
         RAO*  PBEF      BUMP PAST 2ND PARAMETER ADCON
         LR3*  EF1       MICRO-MEMORY ADDRESS OF LOAD FILE1 
         EMS   3
         LR3*  R3SVE     RESTORE R3 
         JMP*  (PBEF)    EXIT 
* 
R3SVE    NUM   0         R3 SAVE AREA 
EF1      NUM   $603      MICRO MEMORY ADDRESS FOR LOAD FILE 1 
DF1      NUM   $604      MICRO MEMORY ADDRESS FOR DISPLAY FILE 1
TOP       ADC    QTOPSK 
* 
          EXT    QTOPSK 
         ENT   PBDF      DISPLAY FILE1(I) 
PBDF     NOP   0
          IIN    0           INHIBIT INTERRUPTS 
         SR3*  R3SVE     SAVE R3
         LDQ*  (PBDF) 
         LDQ   0,Q       GET FILE1 INDEX AND NO. WORDS
         RAO*  PBDF      BUMP RETURN ADDRESS
         LDA*  (PBDF)    GET TRANSFER ADDRESS 
         RAO*  PBDF 
         LR3*  DF1       MICRO-MEMORY ADDR OF DISPLAY FILE1 
         EMS   3
          LDQ*   (TOP)       GET INTERRUPT COUNT
          SQN    PBDF1       COUNT NON ZERO 
          EIN    0           ZERO, ENABLE INTERRUPTS
PBDF1     JMP*   (PBDF)      EXIT 
         END
