*COMDECK  ZFS 
          TITLE  ZFS  -  Z FILE SETUP 
**        ZFS  -  Z FILE SETUP
* 
*         DETERMINE THE FILE NAMES TO BE USED FOR THE PROCEDURE 
*         STACK AND DATA STACK FILES. 
*         THEN OPEN THE FILES.
* 
*         ENTRY  X1 = 1, CALLED BY BEGIN OR ENDW
*                   = 0, CALLED BY REVERT 
  
 ZFS      BSSZ   1           ENTRY/EXIT 
          SA5    SNVPNL 
          SA3    =0L"M.FNPS1" 
          SA4    =0L"M.FNPS2" 
          BX6    X3 
          LX5    59 
          BX7    X4 
          PL     X5,ZFS1     IF PNL EVEN
  
          BX6    X4 
          BX7    X3 
 ZFS1     BSS 
 OSNOSBE  IFNE   HOST,SC2 
          SX0    1
          BX6    X0+X6       SET COMPLETE BIT 
          BX7    X0+X7       SET COMPLETE BIT 
 OSNOSBE  ENDIF 
          SA6    FILEPS 
          SA7    FILEDS 
          BX4    X7 
          ZR     X1,ZFS2     IF CALLED BY REVERT
          NZ     X5,ZFS2     IF NOT FIRST PROCEDURE CALL
  
          BX5    X7          X5= LFN TO BE RETURNED 
          RJ     =XIORTN     RETURN DATA STACK FILE 
  
 OSSC2    IFEQ   HOST,SC2 
          OPENM  FILEDS,I-O,N   OPEN DATA STACK FILE
 OSSC2    ENDIF 
  
          SA5    FILEPS 
          RJ     =XIORTN     RETURN PROCEDURE STACK FILE
  
 OSNOS    IFEQ   HOST,NOS 
          SA5    =0L"M.FNOCS" 
          RJ     IORTN       RETURN FILE
          SA4    =0L"M.FNOCS" 
 OSNOS    ENDIF 
 ZFS2     BSS 
          BX6    X4 
          SA6    FILECS      NAME FOR USE WHEN ACCESS C.S.F.
          JP     ZFS         EXIT 
