*COMDECK  SET 
          TITLE  SET
**        SET  -  SET FIELD TO EXPRESSION 
* 
*         PROCESS THE SET VERB,    SET,SYM=EXP. 
*         THE NAME TO BE SET MUST BE A SETABLE NAME WITHIN
*         THE SNV TABLE.  SETABLE ENTRIES ARE BETWEEN THE 
*         ENTRY 0 AND THE ENTRY DEFINED AS SNVSET.
* 
  
 SET1     BSS 
          SX6    2
          SA6    PROCESS     SET
          RJ     =XCCLGNP    GET NEXT PARAMETER 
          NZ     X5,EXIT2    ABORT IF ERROR 
  
          SA3    ANSSTR 
          SA2    ANSSEP 
          SX7    1R=
          BX6    X3 
          BX0    X2-X7
          SA6    SETNAM 
          SX3    MSG102      SET POSSIBLE ERR MESSAGE 
          NZ     X0,EXIT1    ERR IF NOT AN =
  
*         DETERMINE IF SUBSYSTEM FUNCTION REFERENCE *SS*
  
          SA4    ANSSTR 
          SX7    2RSS 
          LX7    48          LEFT JUSTIFY 
          IX7    X7-X4
          ZR     X7,SETSS    SUBSYSTEM FUNCTION IN SET
  
          RJ     =XCCLEVX    EVALUATE EXPRESSION
          NZ     X5,EXIT2    EXPRESSION INVALID 
  
          SA5    EXPVAL 
          SA1    SETNAM 
          BX6    X5 
          RJ     =XCCLSSV    SET SYMBOLIC NAME TO VALUE 
  
          SX3    MSG159      $FIRST PARAMETER INVALID IN SET FUNCTION$
          ZR     X5,EXIT1    IF VALUE NOT SET 
  
          RJ     =XCCLSJC    SET JOB CONTROL INFO,(WHATEVER WAS SET)
  
          RJ     =XCCLSPP    RESET PAGE PARAMETERS (WHATEVER WAS CHANGED) 
          NZ     X3,EXIT1    ERROR - X3 HAS MESSAGE CODE
  
 SET2     SA1    ANSSEP 
          SX7    1R.
          SX6    1R)
          BX7    X1-X7
          BX6    X1-X6
          ZR     X7,EXIT     IF PERIOD TERMINATOR 
  
          NZ     X6,SET1     IF NOT TERMINATOR SET ANOTHER
  
          JP     EXIT 
  
 SETSS    BSS 
          SX6    =5RSETSS 
          SA6    PROCESS     INDICATE SETSS ENTRY TO CCLXSS 
          RJ     =XCCLXSS    EXECUTE SUBSYSTEM FUNCTION 
  
          NZ     X3,EXIT1    ERROR - X3 HAS MESSAGE CODE
          JP     SET2        CHECK IF LAST VALUE TO BE SET
  
  
 SETNAM   BSS    1           SYMBOLIC NAME TO BE SET
