*COMDECK  IOSTS 
          TITLE  IOSTS - OBTAIN END OF DATA STATUS
**        IOSTS  -  OBTAIN END OF DATA STATUS 
* 
*         REQUIRED TO DETERMINE TYPE OF END OF DATA FOUND 
* 
*         ENTRY  X2 = FIT ADDRESS 
* 
*         EXIT  X1  = 0 IF MID RECORD 
*                     1 IF EOR, EOS, OR EOP 
*                    -1 IF EOI
* 
*         CALLS  WNB=.
* 
  
 IOSTS    SUBR   =
  
 OSSC2    IFEQ   HOST,SC2 
  
          FETCH  X2,FP,X4,5,6,7 
          SX1    -1          ASSUME EOI 
          SX6    X4-100B     EOI
          ZR     X6,IOSTS    EXIT 
  
          SX1    1           INDICATE EOS OR EOP
          SX6    X4-20B      EOS
          ZR     X6,IOSTS    EXIT 
  
          SX6    X4-40B      EOP
          ZR     X6,IOSTS    EXIT 
  
          SX1    0           OTHER POSITION 
          JP     IOSTS       EXIT 
 OSSC2    ELSE
          RECALL X2          WAIT I/O COMPLETE
  
*         CHECK END OF DATA STATUS
*                BIT 09 - EOI 
*                BITS 3 AND 4 - 11B = EOP, 10B = EOR
  
          SA3    X2 
          LX3    59-9 
          SX1    -B1         = -1, EOI STATUS 
          NG     X3,IOSTS    EXIT - EOI STATUS
  
          SX1    B0          = 0, MID RECORD STATUS 
          LX3    9-4
          PL     X3,IOSTS    EXIT - MID RECORD STATUS 
  
          SX1    B1          = 1, EOR, EOS OR EOP STATUS
          JP     IOSTS       EXIT 
  
 OSSC2    ENDIF 
  
  
