*COMDECK  IOSKP 
          TITLE  IOSKP - SKIP SECTIONS
**        IOSKP  -  SKIP
* 
*         SKIP END OF SECTIONS.  EITHER FORWARD OR BACKWARD 
* 
*         ENTRY  X2 = FIT ADDRESS 
*                B2 = NUMBER OF SECTIONS,IF NEG. BACKSPACE -B2
* 
*         EXIT  SKIP COMPLETED
* 
*         STORE CURRENT POSITION IN NON-SCOPE 2 SYSTEMS 
* 
  
 IOSKP    SUBR   =
  
 OSNOSBE  IFNE   HOST,SC2 
          SA5    X2 
          RJ     IOFET       RESET FET POINTERS 
  
 OSNOSBE  ENDIF 
          EQ     B2,B0,IOSKP EXIT WHEN SKIP COUNT IS 0
          NG     B2,IOSKPB   SKIP BACKWARD INDICATOR
  
 OSSC2    IFEQ   HOST,SC2 
  
*         FOR SCOPE 2 FORCE SKIP TO NEXT END OF SECTION 
  
 SKP10    BSS 
          STORE  X2,DX=SKP60,3,6,7
  
          SX3    10000B      SKIP COUNT 
  
*         FOR SCOPE 2  B2 = COUNT OF EOS TO BE SKIPPED
*         SKIPFL  10000B--> CHECK FOR EOS AND REPEAT
*                           UNTIL COUNT IN B2 IS EXHAUSTED
  
          SKIPFL  X2,X3 
  
          JP     SKP10       SKIP SOME MORE 
  
 IOSKPB   BSS 
  
          STORE  X2,DX=SKP20,3,6,7
  
          SX3    10000B 
  
          SKIPBL  X2,X3 
  
          JP     IOSKPB      CONTINUE UNTIL DATA EXIT 
  
 SKP20    BSSZ   1
  
*         DATA EXIT WHEN SKIPPING BACKWARD
  
          FETCH  X2,FP,X4,5,6,7 
  
          SX6    X4-20B      EOS SCOPE 2
          NZ     X6,SKP40    NOT END OF SECTION 
  
          SB2    B2+1        INCREMENT NEGATIVE SKIP COUNT
          LT     B2,B0,IOSKPB  REPEAT 
  
 SKP40    BSS 
  
*         X4 CONTAINS FILE POSITION INDICATOR 
*         SKIP OVER END INDICATOR UNLESS BEGINNING OF FILE/INFORMATION
  
          SX6    X4-2        BEGINNING OF FILE INDICATOR
          ZR     X6,IOSKP    EXIT 
  
          SX6    X4-1        BEGINNING OF INFORMATION 
          ZR     X6,IOSKP    EXIT 
  
*         RESET DATA EXIT FOR SKIP OVER END INDICATOR 
  
          STORE  X2,DX=SKP50,3,6,7
  
          SX3    1           SKIP COUNT 
  
          SKIPFL  X2,X3      SKIP OVER END INDICATOR
  
          JP     IOSKP       EXIT 
  
 SKP50    BSSZ   1
          JP     IOSKP       EXIT 
  
  
 SKP60    BSSZ   1
  
*         END OF DATA EXIT WHEN SKIPPING FOWARD 
  
          SB2    B2-1        DECREMENT SECTION COUNTER
          GT     B2,B0,SKP10 REPEAT 
  
          JP     IOSKP       EXIT 
  
 OSSC2    ELSE
  
*         SKIP FOWARD FOR NOS OR NOS/BE 
  
  
 SKP70    BSS 
          SKIPF  X2,1,0,R 
  
          SB2    B2-B1       DECREMENT SKIP COUNT 
          GT     B2,B0,SKP70 REPEAT 
  
          JP     IOSKP       EXIT 
  
 IOSKPB   BSS 
  
*         SKIP BACKWARD FOR NOS OR NOS/BE 
  
          SKIPB  X2,1,0,R 
  
          SB2    B2+B1       MODIFY SKIP COUNT
          LT     B2,B0,IOSKPB  REPEAT 
  
          JP     IOSKP       EXIT 
  
 OSSC2    ENDIF 
  
  
