*COMDECK  IOCSAE
          TITLE  IOCSA/IOCSE - CONTROL STATEMENT ACCESS/ENTER 
**        IOCSA   -  CONTROL STATEMENT FILE, ACCESS 
* 
*         THE ACCSF MACRO IS USED TO GET ACCESS TO THE CONTROL
*         STATEMENT FILE. 
* 
*         ENTRY  SCOPE 2 AND NOSBE - NONE, THE MACRO WILL PLACE THE LFN 
*                OF THE CURRENT C.S.F. INTO THE WORD FILEIO 
*                NOS - X5 CONTAINS THE LFN TO BE PLACED INTO FILEIO 
* 
*         EXIT   LFN OF CURRENT CONTROL STATEMENT FILE IS WRITTEN TO
*                FILEIO.  WORD CSFPOS CONTAINS FILE POSITION INFORMATION
* 
  
 IOCSA    SUBR   =
  
 OSNOS    IFEQ   HOST,NOS 
  
          SX2    FILEIO      FET TO RECEIVE LFN 
          RJ     IOFET       PLACE LFN FROM X5 INTO FILEIO - X2 
  
 OSNOS    ENDIF 
  
          ACCSF  FILEIO,CSFPOS
  
  
 OSSC2    IFEQ   HOST,SC2 
          MX6    -18
          SA3    FILEIO 
          BX6    X6*X3       ISOLATE LFN ONLY 
          SA6    A3          RESTORE AT FILEIO
  
          SETFIT FILEIO 
  
          GETPOS FILEIO,X6
  
          SA6    CSFPOS      STORE POSITION OF CURRENT FILE 
  
 OSSC2    ELSE
          SA2    FILEIO      SET COMPLETE BIT 
          SX6    B1 
          BX6    X6+X2
          SA6    A2          *FIN* LEFT FET BUSY
  
 OSSC2    ENDIF 
  
          JP     IOCSA       EXIT 
  
  
**        IOCSE   -  CONTROL STATEMENT FILE, ENTER
* 
*         THE ENCSF MACRO IS USED TO ENTER A FILE AS THE
*         NEW CONTROL STATEMENT FILE. 
* 
*         INPUT  X2 IS ADDRESS CONTAINING LFN TO BE ENTERED 
* 
  
 IOCSE    SUBR   =
  
*         STORE LFN FROM ADDRESS SPECIFIED BY X2
  
          SA5    X2 
          SX2    FILEIO 
          RJ     IOFET       RESET FET FIELDS 
  
 OSSC2    IFEQ   HOST,SC2 
  
          SETFIT FILEIO 
  
          SA5    CSFPOS      X5= POSITION 
  
          POSITION FILEIO,X5  REPOSITION FILE 
  
 OSSC2    ENDIF 
  
          ENCSF  FILEIO,CSFPOS
  
  
          JP     IOCSE       EXIT 
  
  
