*COMDECK  CCLWPV
 CCLWPV   TITLE  WRITE PATTERNS AND VALUES
**        CCLWPV - WRITE PATTERNS AND VALUES TO PVT 
* 
* 
*         ENTRY -  X5 = NUMBER OF CHARACTERS IN ENTRY 
*                  A4 = ADDRESS OF 1ST WORD 
*                  X4 = 1ST WORD OF VALUE 
*                  IACPVID = CONTROL WORD FOR EACH ENTRY
* 
*         EXIT -   PVTCL IS UPDATED TO THE OFFSET OF NEXT ENTRY 
*                  PVT ENTRY IS WRITTEN 
*                  IACPVID UPDATED
*                  X5 IS PRESERVED. 
* 
*         USES   X - 1, 2, 3, 4, 5, 6, 7. 
*                A - 1, 2, 3, 4, 6, 7.
*                B - 4, 5, 7. 
  
 CCLWPV   SUBR   =
          SA1    IACPVID           PUT SIZE IN CONTROL WORD 
          SB7    X5 
          ERRNZ  W.PVID-W.PVSIZ 
          ERRNZ  S.PVSIZ-N.PVSIZ+1 REQUIRED FOR PRESERVATION OF X5
          OX6    X1,X5,PVSIZ
          SA6    IACPVID
          SA1    PVTCL             CHECK LENGTH OF TABLE
          SA6    PVT+W.PVID+X1
          SB4    B0 
 WPV00    BSS    0
          LE     B7,B0,WPV001      B4 HAS SIZE OF PVT ENTRY 
  
          SB7    B7-10
          SB4    B4+B1
          JP     WPV00             TEST SIZE AGAIN
  
 WPV001   BSS    0
          SB4    B4+B1             ADD 1 FOR CONTROL WORD 
          SX7    X1+B4
          SX2    X7-L.PVT 
          SX3    MSG323            PVT EXCEEDED 
          PL     X2,BRWERR         EXIT - X3 HAS ERROR CODE 
  
          SA7    PVTCL
          SA3    PPTCL
          SA2    PPT+W.PPLV+X3
          ERRNZ  W.PPLV-W.PPVAL 
          EX6    X2,PPVAL 
          IX1    X1-X6             LENGTH = PVTCL-PPVAL 
          OX7    X2,X1,PPLV        STORE LENGTH OF PVT ENTRIES IN PPT 
          SA7    A2 
          BX6    X4                PUT STRING IN PVT ENTRY
          SB5    X5 
          LE     B5,B0,CCLWPV      RETURN WHEN NULL STRING
  
 WPV005   BSS    0
          SB5    B5-10
          SA6    A6+B1
          LE     B5,B0,CCLWPV      RETURN - STRING PLACED IN PVT
  
          SA4    A4+B1             FETCH NEXT WORD OF STRING
          BX6    X4 
          JP     WPV005            STORE NEXT WORD
  
