*COMDECK  CCLSPP
          TITLE  CCLSPP  -  SET PAGE PARAMETERS 
**        CCLSPP  -  SET PAGE PARAMETERS
* 
*         CALLED BY THE SET VERB PROCESSOR
* 
*         USE MACRO SETPAGE TO RESET PAGE PARAMETERS
* 
*         ENTRY  NONE.
* 
*         EXIT   (X3) = 0 IF NO PARAMETER ERRORS. 
*                (X3) = MESSAGE CODE IF ERRORS. 
* 
*         CALLS  SETPAGE
* 
  
 CCLSPP   SUBR   =
  
*         JOB DEFAULT PRINT DENSITY 
  
          SA1    SNVJPP            FIRST WORD OF JOB PAGE PARAMETERS
          MX0    -N.PGJPD 
          BX6    -X0*X1 
          SX4    X1-JPD6
          ZR     X4,SPP1           ZERO, IF JPD = 6 
  
          SX4    X1-JPD8
          SX3    =C* PD.*          PRESET ERROR FLAG
          NZ     X4,SPP3           IF JPD NOT = 8 
  
*         JOB DEFAULT PAGE SIZE 
  
 SPP1     BSS    0
          SA1    A1+B1
          LX6    N.PGJPS           MAKE ROOM FOR JPS
          MX0    -N.PGJPS 
          BX4    -X0*X1 
          BX6    X4+X6
          SX4    X1-JPSMAX-1
          SA2    SETNAM            CHECK FOR PL SYMBOL
          SX3    =C* PL.* 
          SA5    =0LPL
          BX0    X2-X5
          ZR     X0,SPP1.5         PL SYMBOL - USE PL ERROR MESSAGE 
  
          SX3    =C* PS.* 
  
 SPP1.5   BSS    0
          PL     X4,SPP3           IF JPS .GT. MAX
  
          SX4    X1-JPSMIN
          NG     X4,SPP3           IF JPS .LT. MIN
  
          SA1    A1+B1             TEST PL PARAMETER VALUES 
  
*         JOB DEFAULT PAGE WIDTH
  
          SA1    A1+B1
          LX6    N.PGJPW           MAKE ROOM FOR JPW
          MX0    -N.PGJPW 
          BX4    -X0*X1 
          BX6    X4+X6
          LX6    S.PGJPW-N.PGJPW+1
          SX4    X1-JPWMAX-1
          SX3    =C* PW.* 
          PL     X4,SPP3           IF JPW .GT. MAX
  
          SX4    X1-JPWMIN
          NG     X4,SPP3           IF JPW .LT. MIN
  
          SA4    SPP               GET ORIGINAL JOB PAGE PARAMETERS 
          BX4    X4-X6
          AX4    1                 REMOVE COMPLETION BIT
          ZR     X4,SPP2           IF JOB PARAMETERS NOT CHANGED
  
          SA6    A4                STORE UPDATED PAGE PARAMETER WORD
          SETPAGE SPP              RESET PAGE PARAMETERS
  
 SPP2     BSS    0                 CLEAR ERROR FLAG 
          SX3    0
          JP     CCLSPP            RETURN 
  
 SPP3     BSS    0
          SX4    MSG164            PAGE PARAMETER ERROR MESSAGE 
          LX3    18 
          BX3    X3+X4
          JP     CCLSPP            RETURN 
  
