*COMDECK  CCLSNV
          TITLE  CCLSNV - SYMBOLIC NAME VALUES
**        CCLSNV  -  SYMBOLIC NAME VALUE
* 
*         THE SYMBOLIC NAMES KNOWN TO CCL ARE EXAMINED. 
*         IF THE NAME IS FOUND, THE VALUE OF THAT SYMBOL
*         IS RETURNED.
*         THERE ARE TWO SYMBOL TABLES.  THE NOMINAL ONE IS
*         LOCATED IN THE COMMON DECK CCLCOM1.(SNVT) 
*         WHEN WITHIN THE FILE FUNCTION THEN THE TABLE
*         SNVFIL IS USED.  IT IS LOCATED IN CCLEVX FOLLOWING
*         THE FILE FUNCTION CODE. 
* 
*         ENTRY  X1  = NAME, LEFT JUSTIFIED 
* 
*         EXIT   X5  = FLAG, 1= SYMBOL FOUND  ELSE 0=NOT FOUND
*                X6  = VALUE IF FOUND 
* 
  
 CCLSNV   SUBR   =
          SA4    EVXFIL 
          SA2    SNVT 
          MX0    N.SNVNAM 
          SX5    B0          PRESET FLAG TO NOT FOUND 
          SB7    SNVEIGHT+1  FOR MINIMUM SIZE SYMBOL COMPARISON 
          ZR     X4,SNV1     IF NOT WITHIN FILE FUNCTION
          SA2    SNVFIL      USE SYMBOLS FOR FILE FUNCTION
 SNV1     BSS 
          BX3    X0*X2
          ZR     X2,CCLSNV   EXIT IF END OF TABLE,NOT FOUND 
          BX4    X2 
          BX7    X3-X1       COMPARE
          SA2    A2+B1
          NZ     X7,SNV1     IF NOT A MATCH 
  
*         FOUND 
  
          SX6    A2-B7
          NG     X6,SNV3     IF NOT A MINIMUM SIZE SYMBOL 
  
          SX6    X6-SNVZERO+SNVEIGHT
          PL     X6,SNV3     IF NOT A MINIMUM SIZE SYMBOL 
  
          SX7    2*6
          SX6    X6-SNVTWO+SNVZERO
          PL     X6,SNV2     IF TWO DIGIT MINIMUM SIZE
  
          SX7    4*6
          SX6    X6-SNVFOUR+SNVTWO
          PL     X6,SNV2     IF FOUR DIGIT MINIMUM SIZE 
  
          SX7    6*6
          SX6    X6-SNVSIX+SNVFOUR
          PL     X6,SNV2     IF SIX DIGIT MINIMUM SIZE
  
          SX7    8*6
 SNV2     SA7    DISTIME     SET MINIMUM SIZE FOR VALUE 
  
 SNV3     BSS    0
          EX6    X4,SNVVAL
          LX4    59-S.SNVOFF SHIFT FLAG TO SIGN BIT 
          SX5    B1          FOUND FLAG 
          PL     X4,CCLSNV   VALUE IN X6, EXIT
  
          SA4    SNVWRD+X6   GET VALUE
          BX6    X4          VALUE
          JP     CCLSNV      EXIT 
  
