*COMDECK  CCLSJC
          TITLE  CCLSJC  -  SET JOB CONTROL INFO
**        CCLSJC  -  SET JOB CONTROL INFORMATION
* 
*         USE THE SETJCI MACRO TO RESET SYSTEM VALUES 
*         RATHER THAN REMEMBERING WHICH VALUES HAVE BEEN CHANGED
*         CCLSJC WILL SIMPLY RESET ALL VALUES WHICH MAY HAVE
*         CHANGED.
* 
  
 CCLSJC   SUBR   =
          SA1    SNVR1
          SA2    SNVR2
          SA3    SNVR3
  
*         THE VALUES OF R1,R2,R3,R1G ARE SAVED AS 18 BIT, SIGNED
*         QUANTITIES.  IF THE VALUE IS LARGER IT IS TRUNCATED TO
*         THE LOWER 17 BITS AND THE SIGN BIT IS SAVED.
  
          MX0    60-N.JCR1+1
          MX4    1
          BX5    X1*X4       EXTRACT THE SIGN BITS
          BX6    X2*X4
          BX7    X3*X4
          SA4    SNVEF
          LX5    N.JCR1 
          LX6    N.JCR2 
          LX7    N.JCR3 
          BX1    -X0*X1 
          BX2    -X0*X2 
          BX3    -X0*X3 
  
*         SET THE SIGN BIT INTO BIT 18
  
          BX1    X1+X5
          BX2    X2+X6
          BX3    X3+X7
          MX6    -N.JCEF
          BX4    -X6*X4 
          LX3    S.JCR3-N.JCR3+1
          LX2    S.JCR2-N.JCR2+1
          LX4    S.JCEF-N.JCEF+1
          BX7    X1+X2
          BX6    X3+X4
          BX7    X6+X7
          SA7    JCI+W.JCEF  STORE EF,R1,R2,R3
          ERRNZ  4-W.JCEF-W.JCR1-W.JCR2-W.JCR3
          SA1    SNVSSW      SW1
          MX7    0
          SB7    B0 
          SB6    6
          MX6    1
          MX0    -N.SNVVAL
 SJC1     BSS 
          LX6    1
          BX4    -X0*X1 
          SB7    B7+B1
          SA1    A1+B1
          ZR     X4,SJC2     IF NOT TO BE SET 
          BX7    X6+X7       SET SSW IF FIELD NON-ZERO
 SJC2     BSS 
          LT     B7,B6,SJC1  IF MORE SSW
  
          SA1    SNVR1G 
          SA2    SNVEFG 
          SA3    SNVEM
          LX7    S.JCSSW-N.JCSSW+1
          MX4    1
          MX0    60-N.JCR1G+1 
          BX4    X1*X4       EXTRACT SIGN BIT 
          MX5    -N.JCEFG 
          MX6    -N.JCEM
          LX4    N.JCR1G
          BX1    -X0*X1 
          BX2    -X5*X2 
          BX1    X1+X4       RESET UPPER BIT OF FIELD TO SIGN BIT 
          BX3    -X6*X3 
          LX1    S.JCR1G-N.JCR1G+1
          LX2    S.JCEFG-N.JCEFG+1
          LX3    S.JCEM-N.JCEM+1
          BX7    X1+X7
          BX2    X2+X3
          BX7    X2+X7
          SA5    SNVPNL      PNL
          SA4    SNVDSC      DSC
          MX0    -N.JCPNL 
          MX6    1
          BX5    -X0*X5 
          LX5    S.JCPNL-N.JCPNL+1
          LX6    S.JCDSC+1
          BX7    X5+X7
          ZR     X4,SJC3     IF DSC=FALSE 
  
          BX7    X6+X7       SET JCDSC IF DSC=TRUE
 SJC3     BSS 
          ERRNZ  W.JCEFG+W.JCR1G+W.JCDSC+W.JCEM+W.JCSSW 
          SA7    JCI+W.JCEFG
  
*         SET JOB CONTROL INFORMATION 
  
          SETJCI JCI
  
          JP     CCLSJC      EXIT 
  
