*COMDECK  CCLNPV
 CCLNPV   TITLE  NEXT PATTERN VALUE 
**        CCLNPV - NEXT PATTERN VALUE ENTRY FROM PVT
* 
* 
*         CCLNPV READS PARAMETER CHECKLIST PATTERNS AND VALUES. 
*         THESE PATTERNS AND VALUES ORIGINATED FROM THE PROCEDURE 
*         HEADER AND ARE NOW STORED IN THE PATTERN VALUE TABLE (PVT). 
*         CCLNPV RETURNS THE PVT CONTROL WORD TO THE
*         CALLER IN X2.  THEN CCLNPV CALCULATES THE LENGTH OF THE 
*         CURRENT ENTRY AND UPDATES THE OFFSET OF THE NEXT ENTRY. 
*         IACPRE IS SET TO THE CURRENT OFFSET.  IACNPV IS UPDATED 
*         TO THE NEW OFFSET.  X2 IS SET TO ZERO WHEN THE LAST PVT 
*         ENTRY FOR THIS PARAMETER HAS BEEN PROCESSED.  IACNPV
*         EXCEEDS IACLPE
* 
*         ENTRY - IACNPV = NEXT OFFSET
*                 IACPRE = PREVIOUS OFFSET
*                 IACLPE = LAST OFFSET
*                 X4 = 1ST WORD OF CALL STATEMENT VALUE 
*                 X5 = SIZE OF VALUE
* 
*         EXIT  - X2 = PVT CONTROL WORD 
*                 X2 = 0 ALL ENTRIES PROCESSED
*                 A2 = ADDRESS OF CURRENT PVT CONTROL WORD
*                 X0 = PVID LEFT JUST ZERO FILL 
*                 B2 = NUMBER OF CHARACTERS IN PVT ENTRY (PVSIZ)
*                 X4 = 1ST WORD OF CALL VALUE PRESERVED 
*                 X5 = SIZE OF CALL VALUE PRESERVED 
* 
*         REGISTERS SAVED - A4,A5  X4,X5
* 
* 
 CCLNPV   SUBR   =
          MX2    0
          SA1    IACNPV            NEXT PVT OFFSET
          SA3    IACLPE            LAST PVT OFFSET
          IX0    X3-X1
          NG     X0,CCLNPV         ALL ENTRIES PROCESSED - RETURN 
  
          SA2    PVT+W.PVID+X1     PVT ENTRY CONTROL WORD 
          ERRNZ  W.PVID-W.PVSIZ 
          EX0    X2,PVSIZ 
          SB2    X0 
          SB4    B0 
 NPV00    BSS    0
          LE     B2,B0,NPV010      B4 CONTAINS SIZE OF PVT ENTRY
  
          SB2    B2-10
          SB4    B4+B1
          JP     NPV00             TEST SIZE
  
 NPV010   BSS    0
          SB4    B4+B1             ADD 1 TO SIZE FOR CONTROL WORD 
          SX7    X1+B4             UPDATE OFFSET TO NEXT PVT ENTRY
          SA1    IACNPV            PREVIOUS PVT ENTRY OFFSET
          BX6    X1 
          SA6    IACPRE 
          SA7    IACNPV 
          MX3    N.PVID 
          ERRNZ  59-S.PVID
          BX0    X2*X3             EXTRACT PVID 
          BX3    X2 
          EX6    X2,PVSIZ 
          SB2    X6 
          JP     CCLNPV            RETURN TO CALLER 
  
