*COMDECK  CCLIDC
 CCLIDC   TITLE  INITIALIZE DIALOGUE CONDITIONS 
**        CCLIDC - INITIALIZE INTERACTIVE DIALOGUE CONDITIONS 
* 
*         ENTRY - IF IACIDP(DIALOGUE IN PROGRESS) RETURN
*                 ELSE CONNECT FILES (NOSBE)
*                 TURN OFF ASCII MODE (NOS) 
* 
*         EXIT  - IACIDP SET TO 1 (DIALOGUE IN PROGRESS)
* 
* 
 CCLIDC   SUBR   =
          SA1    IACIDP 
          NZ     X1,CCLIDC         DIALOGUE IN PROGRESS - RETURN
  
 OSNOSBE  IFNE   HOST,SC2 
          SA1    SNVOT
          MX2    -N.RAJOT          GET JOB ORIGIN 
          BX6    -X2*X1 
          SX0    X6-SD.TXO
          NZ     X0,CCLIDC         BATCH ORIGIN - RETURN
  
 SDOVL    IFNE   IP.SDO,0 
          SA1    IACIMP 
          NZ     X1,IDC005         IF MENU PROC SKIP SIZE CHECK 
  
          SA1    IACLCP            CHECK LONGEST CHECKLIST PATTERN
          SX1    X1-41
          PL     X1,IDC010         IF LONGEST OVER 40 NO SCREEN MODE
  
 IDC005   BSS    0
          SA1    SDMODE            CHECK FOR SCREEN MODE
          ZR     X1,IDC050         LINE MODE
  
  
*         CALL SCREEN DIALOGUE OVERLAY
  
          MEMORY ,,R,65000B 
  
 SDLOC    IFEQ   IP.LCL,0 
          SYSTEM LDR,R,IDCLDR 
  
          SA1    IDCLDR+1 
          MX0    -18
          BX7    -X0*X1 
 SDLOC    ELSE
  
          OVERLAY IDCLDR,0100B
  
          BX7    X1 
 SDLOC    ENDIF 
  
          SX6    2
          SA7    SDENTRY           STORE ENTRY ADDRESS
          SA6    IACIDP            SET SCREEN MODE INDICATOR
          JP     CCLIDC            RETURN 
  
 IDC010   BSS    0
          SX7    B0+               CLEAR OUT SCREEN MODE INDICATOR
          SA7    SDMODE 
  
 IDC050   BSS    0                 CHECK SCREEN X AND Y 
  
 SDOVL    ENDIF 
 OSNOS    IFEQ   HOST,NOS 
  
*         SET LIST OF FILES FOR FLUSHING OF I/O BUFFERS 
  
          SETLOF IDCPTL            POINTER TO LIST
  
          CSET   NORMAL            TURN OFF ASCII MODE AT THE TERMINAL
  
 OSNOS    ELSE
  
  
*                                  CONNECT NOSBE INTERCOM I/O 
          SA5    =0L"M.FNIN"       NAME OF INTERCOM INPUT 
          BX7    X5 
          SA7    FNIN              CONNECT PARAMETER WORD 
          SX2    I
  
          RJ     =XIOFET           SET FET FIELDS 
  
          SA3    O+W.FEAI 
          MX0    1
          LX0    1
          OX7    X3,X0,FEAI        SET ALLOW INTERCOM BIT 
          SA7    A3 
          MX0    1
          MX3    0
          LX0    1
          OX7    X3,X0,FE128       SET ASCII 128 MODE 
          SA7    O+W.FE128
          SA5    =0L"M.FNOU"
          BX7    X5 
          SA7    FNOU              CONNECT PARAMETER WORD 
          SX2    O
  
          RJ     =XIOFET           SET FET FIELDS - OUTPUT FILE 
  
          SYSTEM CON,R,FNIN,0      CONNECT INTERCOM I/O 
          SYSTEM CON,R,FNOU,0 
  
 OSNOS    ENDIF 
          SX7    1
          SA7    IACIDP 
 OSNOSBE  ENDIF 
          JP     CCLIDC            RETURN 
  
  
 OSNOS    IFEQ   HOST,NOS 
 IDCPTL   BSS    0
          VFD    12/0,18/IDCLOF,30/0
 IDCLOF   BSS    0
          VFD    1/0,41/0,18/3
          VFD    42/6LOUTPUT,18/OUTPUT
          VFD    60/0 
 SDOVL    IFNE   IP.SDO,0 
  
 IDCLDR   BSS    0                 OVERLAY LOAD REQUEST TABLE 
  
 SDLOC    IFEQ   IP.LCL,0 
          VFD    42/3LSDO,18/0
  
          VFD    6/1               LEV1 
          VFD    6/0               LEV2 
          VFD    1/0               N
          VFD    4/0               RESERVED 
          VFD    1/1               U
          VFD    1/1               V
          VFD    4/0               RESERVED 
          VFD    1/0               COMPLETION BIT 
          VFD    18/0              LWA+1
          VFD    18/0              FWA
  
 SDLOC    ELSE
          CON    4LCCLX 
  
 SDLOC    ENDIF 
 SDOVL    ENDIF 
  
 OSNOS    ENDIF 
