*COMDECK  CCLGNO
 CCLGNO   TITLE  CCLGNO - GET NEXT OPERAND (EXPRESSIONS)
**        CCLGNO - GET NEXT OPERAND (EXPRESSIONS) 
* 
* 
*         IF A .IF CONDITIONAL STATEMENT IS NOT BEING PROCESSED,
*         CCLGNO WILL RETURN JUMP TO CCLGNP AND THEN RETURN.
* 
*         CCLGNO RETURNS WITH A STRING AND ITS FOLLOWING
*         SEPARATOR (STRANS). 
* 
*         IF THE END OF SCATBF1 IS REACHED (.IF), THE BUFFER
*         MUST BE REFRESHED.  IF THE PREVIOUS PROCEDURE BODY
*         LINE WAS EXPANDED COMPLETELY (MOREXP = 0), A NEW LINE 
*         MUST BE READ FROM THE PROCEDURE BODY AND EXPANDED.
*         OTHERWISE CCLEXP MUST FINISH EXPANDING THE REMAINDER
*         OF THE PREVIOUS LINE. 
* 
*         ENTRY - SCATBF1 CONTAINS LINE WITH EXPRESSION 
* 
*         EXIT - X5 = 0 - OK
*                X5 = 1 - ERROR - X3 HAS CODE 
* 
* 
 CCLGNO   SUBR   =
  
 GNO10    BSS    0
          SA2    SCATBF1
          RJ     =XSTRANS 
          SA3    IACERR 
          NZ     X3,GNO30          SET ERROR FLAG 
  
  
          SA4    ANSSEP 
          MX5    0
          PL     X4,CCLGNO         RETURN - STRING AND SEPARATOR
  
          SA4    ANSCHR 
          SX3    MSG101            LAST CHARACTER MUST BE SEP.
          NZ     X4,GNO30          SEND ERROR MSG 
  
          SA1    MOREXP 
          NZ     X1,GNO20          EXPAND REMAINDER OF LINE 
  
          SX6    SCATBF2           GET NEXT LINE FROM PROC BODY 
          SX2    FILEPC 
          SX3    PROCWSA
          SX4    V.CCCPC
          RJ     =XIORDL           READ LINE
  
          SX3    MSG376            .IF INCOMPLETE 
          NZ     X1,GNO30          EOF BEFORE STATEMENT COMPLETE
  
          SA2    SCATBF2
          SA3    PROCSEQ           CHECK FOR SEQUENCE NUMBERS 
          ZR     X3,GNO20          NO SEQUENCE NUMBERS
  
          RJ     CCLSSN            SKIP SEQUENCE NUMBERS
  
 GNO20    BSS    0
  
          RJ     CCLEXP            EXPAND LINE
  
          JP     GNO10             NEXT OPERAND 
  
 GNO30    BSS    0                 SET ERROR FLAG 
          SX5    1                 INDICATE ERROR 
          JP     CCLGNO            RETURN 
  
