*COMDECK  CCLCCN
          TITLE  CCLCCN  -  CONTROL CARD, NEXT
**        CCLCCN  -  CONTROL CARD, NEXT 
* 
*         USES THE CONTRLC MACRO TO GET THE NEXT CONTROL CARD 
*         INTO THE COMMUNICATION AREA. (W.RACS = 70B) 
*         IF SKIPPING IS NOT IN PROCESS, THE CARD IMAGE MUST BE 
*         DISPLAYED ON THE DAYFILE.  ON SCOPE 2 THE CARD OBTAINED MAY 
*         HAVE ALREADY BEEN WRITTEN TO THE DAYFILE BY THE LOADER. 
*         (THE LOADER MAY HAVE READ THE CARD, CCLCCF BACKSPACED 
*         OVER IT AND NOW CCLCCN MAY REREAD IT).  CCLCCN MUST 
*         DETERMINE IF IT HAS BEEN DISPLAYED AND IF NOT THEN DO SO. 
*         WRITE THE CARD TO THE DAYFILE.
* 
*         EXIT   X5 = 0, IF OK ELSE X5=1 IF ERROR 
  
  
 CCLCCN   SUBR   =
          MX6    0
          SB6    7
          SA6    W.RACS 
 CCN1     BSS 
          SB6    B6-B1
          SA6    A6+B1
          LT     B0,B6,CCN1  IF MORE TO ZERO
  
 OSSC2    IFEQ   HOST,SC2 
          SX7    10B
          SA7    CCNADR 
          CONTRLC CCNADR
  
          SA1    CCNADR 
          SX1    X1-1 
          NZ     X1,CCN4     IF NOTHING READ, AT END OF FILE
 OSSC2    ENDIF 
 OSBE     IFEQ   HOST,NOSBE 
          MX7    0
          SA7    CCNADR 
          CONTRLC CCNADR,READ 
  
          SA1    CCNADR 
          LX1    59-4        POSITION BIT 4 TO SIGN BIT 
          NG     X1,CCN4     IF NO CARD READ
 OSBE     ENDIF 
 OSNOS    IFEQ   HOST,NOS 
          MX7    0
          SA7    CCNADR 
          CONTROL W.RACS,,LF
  
          SA1    W.RACS 
          NZ     X1,CCN3     IF CARD READ 
  
          JP     CCN4        AT END OF CONTROL STATEMENT FILE 
 OSNOS    ENDIF 
  
*         IF CCLCCN WAS CALLED DURING SKIPPING, EXIT. 
*         (SKIPPED CARDS ARE PRINTED ELSEWHERE) 
  
 CCN3     BSS 
          SA2    CCSKIP 
          MX5    0           POSSIBLE EXIT CODE=  OK
          NZ     X2,CCLCCN   EXIT IF SKIPPING 
  
*         IF CCDF IS POSITIVE, SEND CARD IMAGE TO DAYFILE 
*         (THE LOADER DID NOT PROCESS THIS CARD)
  
 OSSC2    IFEQ   HOST,SC2 
          SA4    CCDF 
          SX3    W.RACS 
          SX7    X4+B1
          SA7    A4 
          NG     X4,CCLCCN   EXIT IF NOT TO PRINT 
  
 OSSC2    ENDIF 
  
 OSNOSBE  IFNE   HOST,SC2 
          SX7    B0+         CLEAR COMMAND IMAGE DISPLAYED FLAG 
          SA7    CCDF 
          SA1    RSTRICT
          NZ     X1,CCLCCN   IF RESTRICTED PARAMETER(S) EXIT
  
 OSNOSBE  ENDIF 
  
          RJ     DCI         DISPLAY COMMAND IMAGE
  
          MX5    0           EXIT CODE=  OK 
          JP     CCLCCN      EXIT 
  
 CCN4     BSS 
          SX5    1           ERROR CODE 
          JP     CCLCCN      EXIT 
  
 CCNADR   BSS    1
  
  
