*DECK BASSRE
          IDENT  BASSRE1
          ENTRY  BASTSRE,BASXSRE
          TITLE  BASTSRE - SREP$(A$,M,B$,C$) INTERFACE -A-. 
          COMMENT BASIC 3 - SREP$(A$,M,B$,C$) INTERFACE -A-.
*CALL ERMNUM
          CON    10HBASTSRE 
  
 BASTSRE  PS                 ENTRY/EXIT 
          RJ     =XBASSBR=   SAVE REGISTERS 
          SA2    A5          PICK UP ARGUMENTS FROM X5/A5 STACK 
          SA3    A5+B1
          SA4    A3+B1
          SA5    A4+B1
          SA2    X2+B2       A$ POINTER 
          SA3    X3+B2       M (VALUE)
          SA4    X4+B2       B$ POINTER 
          SA5    X5+B2       C$ POINTER 
          SX6    X2 
          PL     X2,SRE1
          SX6    X2+B4
 SRE1     SX7    X4 
          PL     X4,SRE2
          SX7    X4+B4
 SRE2     AX2    18+18
          SA6    ADD1        FWA - 1
          AX4    18+18
          SX6    X2 
          SA7    ADD2        FWA - 2
          SA6    A6+B1       LEN - 1
          SX7    X4 
          SA7    A7+B1       LEN - 2
          SX6    X5 
          PL     X5,SRE3
          SX6    X6+B4
 SRE3     SA6    ADD3        FWA - 3
          AX5    18+18
          UX7    X3,B2
          SX6    X5 
          SA6    A6+B1       LEN - 3
          LX7    X7,B2
          SA7    A6+B1       M
          SA1    CALL 
          RJ     =XBASSRE    GO DO IT 
          RJ     =XBASRBR=         RESTORE REGISTERS
          SB7    X6 
          SX7    B7-B2             STRPOINT MINUS B2
          SA7    SREA 
          JP     BASTSRE           RETURN 
          SPACE  4
 SREA     CON    0
 CALL     CON    ADD1        FTN/SYMPL CALL BLOCK 
          CON    LEN1 
          CON    ADD2 
          CON    LEN2 
          CON    ADD3 
          CON    LEN3 
          CON    M
          CON    0
  
 ADD1     CON    0           ADDRESS OF A$
 LEN1     CON    0           LENGTH OF A$ 
 ADD2     CON    0           ADDRESS OF B$
 LEN2     CON    0           LENGTH OF B$ 
 ADD3     CON    0           ADDRESS OF C$
 LEN3     CON    0           LENGTH OF C$ 
 M        CON    0           STARTING POSITION
          SPACE  4
 BASXSRE  BSS    0                 LWA+1 OF SREP$ PROCESSOR 
          END 
