*DECK BASSFGS 
          IDENT  BASSFGS
          ENTRY  BASSBR=
          ENTRY  BASRBR=
          ENTRY  REG= 
          ENTRY  BAS.MOD
          TITLE  BASSFGS - BASIC 3 - STRING FUNCTION GENERAL SUBROUTINES
          COMMENT BASIC 3 - STRING FUNCTION GENERAL SUBROUTINES.
          SPACE  4
**        BASSBR= - SAVE B1-B5, A0. 
  
 BASSBR=  PS                 ENTRY/EXIT 
          SX6    B1 
          SX7    B2 
          SA6    B
          SB1    1
          SA7    A6+B1
          SX6    B3 
          SX7    B4 
          SA6    A7+B1
          SA7    A6+B1
          SX6    B5 
          SX7    A0 
          SA6    A7+B1
          NO
          SA7    A6+B1
          EQ     BASSBR=     RETURN 
          SPACE  4
**        BASRBR= - RESTORE B1-B5, A0.
  
 BASRBR=  PS                 ENTRY/EXIT 
          SA1    B+1
          SB1    1
          SB2    X1 
          SA2    A1+B1
          SA1    A2+B1
          SB3    X2 
          SB4    X1 
          SA2    A1+B1
          SA1    B
          SB5    X2 
          SB1    X1 
          SA2    A2+1 
          SA0    X2 
          EQ     BASRBR=     RETURN 
          SPACE  4
 REG=     CON    0
 B        BSSZ   6
 MOD      SPACE  4,2
**        BAS.MOD - RETURN MODULO AND DIV OF X2 BY 10.
* 
*         ENTRY  (X2) = M.
* 
*         EXIT   (X6) = M DIV 10 (INTEGER DIVISION).
*                (X7) = M MOD 10 (MODULO - INTEGER DIVISION REMAINDER). 
* 
*         USES   X - 0, 1, 2, 4, 6, 7.
*                A - NONE.
*                B - 7. 
  
  
 BAS.MOD  PS                 ENTRY/EXIT 
          SX1    10 
          PX2    X2 
          PX1    X1 
          NX4    X1 
          RX0    X2/X4
          MX4    77B
          PX4    X4 
          FX4    X4+X0
          DX1    X1*X4
          UX6    X0,B7
          IX7    X2-X1       MODULO 
          LX6    X6,B7       DIV
          EQ     BAS.MOD     RETURN 
          SPACE  4
          END 
