*DECK     BASCARD 
         IDENT     BASCARD                                              001160
         ENTRY     BASCARD                                              001170
*CALL COPYRITE
* 
          DATA   H* COPYRIGHT CONTROL DATA CORPORATION *
          DATA   C* 1975,1976,1977,1978,1979,1980,1981,1982 * 
* 
          EJECT                                                         000390
          IPARAMS                                                       000400
          EJECT                                                         000410
**********************************************************************
**                                                                   *
*         PROGRAM CCP                                                *
*                THIS ROUTINE INITIALIZES OPTIONS FROM A BASIC       *
*                CONTROL CARD. LOW CORE IS CLEARED AND THE           *
*                OPTIONS SELECTED ARE EXTRACTED AND THEIR            *
*                DEFAULT OR FILENAME VALUES ARE STORED IN            *
*                THE PROPER LOW CORE LOCATIONS.                      *
*                                                                    *
**********************************************************************
          SST 
          SYSCOM
          COMMENT BASIC 3 - CONTROL CARD CRACKING.
          IFC   EQ,,"OS.NAME",SCOPE , 
 ACTR     EQU   64B 
          ENDIF 
* 
          EXT   BASSYS=,BASMSG= 
 SYS=     EQU   BASSYS= 
 MSG=     EQU   BASMSG= 
          EXT    DEFPD
* 
* 
 COMPSIZ  EQU    35000B      COMPILER LOAD FL 
*CALL,LCORE 
*CALL,LIPARAM 
          EJECT 
* 
*         PROCEDURE CONTROLCARD 
* 
* 
 BASCARD  PS
          IFC    EQ,,"OS.NAME",KRONOS,
 CCP      BSS    0           SCAN CARD IMAGE
          SA1    JOPR 
          LX1    36 
          SX6    77B         X6 - MASK FOR JOB ORIGIN CODE
          BX1    X6*X1       X1 - 2 DIGIT JOB ORIGIN CODE IN LOW ORDER
          SX6    X1-TXOT
          NZ     X6,CCP1
          SA6    OPOUT+LOPTION         DEFAULT NO LIST ON INTERACTIVE JOB 
          EQ     BASBYE 
 CCP1     BSS    0
          SA3    IBSW 
          BX6    X3 
          ELSE
**********************************************************************
**                                                                   *
*                IN THE SCOPE CASE CALL THE PP ROUTINE RWE           *
*                TO DETERMINE IF THE JOB IS UNDER THE CONTROL        *
*                OF INTERCOM                                         *
*                                                                    *
*         RESPONSE  3  -  JOB UNDER INTERCOM                         *
*                   1  -  BATCH JOB                                  *
*                                                                    *
**********************************************************************
* 
          SYSTEM RWE,R,ADRRWE,
 WAITRSP  SA1    ADRRWE            LOAD RESPONSE WORD 
          BX6    X1 
          LX6    59                CHECK COMPLETION BIT 
          PL     X6,WAITRSP        LOOP IF NOT SET
          SX6    B0                CLEAR REG
          LX1    58                CHECK JOB TYPE 
          NG     X1,ICOM           JUMP IF INTERCOM JOB 
          SA3    =L*BASIC$*        JOB IS BATCH.
          BX6    X3                SET IBFLG TO *BASIC$*
          EQ   BASBYE 
ICOM      BSS    0                 IF INTERCOM JOB, DO NOT SET IBFLG
          SA6    OPOUT+LOPTION         DEFAULT NO LIST ON 
* 
          ENDIF 
 BASBYE   SA6    IBFLG       INTERACTIVE/BATCH FLAG 
          GETPAGE  PGSIZE    GET PAGE SIZE PARAMETERS 
          SA3    PGSIZE      GET JOB PAGE SIZE PARAMETERS 
          MX0    -4 
          LX3    59-27       POSITION JPD 
          BX6    -X0*X3 
          SB7    X6-8 
          MX0    -8 
          LX3    8           POSITION JPS 
          BX6    -X0*X3 
          SA6    OPOUT+PSOPTION  SET JOB PAGE SIZE
          SA6    OPDEFT+PSOPTION
          NZ     B7,CCP2     IF PRINT DENSITY IS NOT 8
          SA3    PD8         GET 8 LPI FORMAT EFFECTOR
          BX6    X3 
          SA6    DEFPD       CHANGE DEFAULT PRINT DENSITY 
          SA6    OPOUT+PDOPTION  SET JOB PRINT DENSITY
 CCP2     BSS    0
          SB1    1
          SA1    ACTR 
          SB7    X1          PARAMETER COUNTER
          SA1    B1 
          MX0    18          MASK FOR OPTION
          SB6    ENDOFOPT+1 
          SX5    77B
          MX7    1
          LX7    19          TO SET OPTION SPECIFIED BIT ON 
          MX4    42          MASK FOR FILE NAMES
* 
* 
*         GETS NEXT OPTION SPECIFIED ON CONTROL CARD
* 
* 
 NEXT     BSS    0
          ZR     B7,ENDCHR   END OF OPTIONS 
          SB7    B7-B1
          SB5    B0 
          SA1    A1+B1
          SB2    X1          SEPARATOR
          BX6    X1*X0       OPTION 
          SA6    PARERR+3 
          SA6    LFNERR+2    SAVE OPTION BEING PROCESSED FOR ERROR
 NEXT1    BSS    0
          SA3    OPTABLE+B5 
          BX2    X0*X3
          BX2    X2-X6
          ZR     X2,OPEQ     OPTION MATCHED 
          SB5    B5+B1
          GT     B5,B6,ERROR NO SUCH OPTION 
          EQ     NEXT1
          EJECT 
* 
*         FOUND OPTION
*           IF SEPARATOR IS EQUAL SIGN BRANCH TO PRC.1
* 
* 
* 
 OPEQ     BSS    0
          SA2    OPTABLE+B5        CK OPTION SPECIFIED BIT
          LX2    41 
          NG     X2,ERROR          ERR BR IF OPTION ALREADY SPECIFIED 
          BX6    X7+X3
          SA6    OPTABLE+B5  SET OPTION SPECIFIED BIT 
          SB3    B2-KEQU
          ZR     B3,OPEQ1    IF KRONOS =
          SB2    B2-TEQU
          NZ     B2,PRC.1    SEPARATOR NOT EQUAL SIGN 
 OPEQ1    SB2    X3 
          JP     B2          APPROPRIATE ROUTINE
* 
* 
* 
*         USE DEFAULT VALUE FOR OPTION
* 
* 
 PRC.1    BSS    0           OPTION, MEANS DEFAULT VALUE TO BE USED 
          SA2    OPDEFT+B5   GET DEFAULT VALUE
          BX6    X2 
          SA6    OPOUT+B5    STORE IN OPOUT 
          EQ     NEXT 
* 
* 
* 
* 
*         (I,L,B,E,J,K)=(0,LFN) 
* 
* 
 PRC.2    BSS    0           (I,L,E,B,J,K)=(0,LFN)
          RJ     NEXTP       GET NEXT PARAMETER 
          SA2    ZERO 
          BX2    X2-X6
          NZ     X2,PRC.21   PARAMETER IS NOT 0 
          SB2    B5-EOPTION 
          ZR     B2,ERROR    EOPTION CANNOT BE 0
          SB2    B5-KOPTION 
          ZR     B2,ERROR    KOPTION CANNOT BE 0
          SB2    B5-IOPTION 
          ZR     B2,ERROR    IOPTION CANNOT BE 0
          BX6    X6-X6
          SA6    OPOUT+B5    PARAMETER IS 0 
          EQ     NEXT 
* 
* 
*         CHECK FOR VALID LFN 
* 
* 
 PRC.21   BSS    0
          LX1    6
          BX1    X5*X1
          SX2    X1-1R0 
          PL     X2,FILERR   FIRST CHARACTER NOT ALPHA
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
*         (AS,BL)=(0) 
* 
* 
 PRC.3    BSS    0
          RJ     NEXTP       GET NEXT PARAMETER 
          SA2    ZERO 
          BX6    X2-X6
          NZ     X6,ERROR    PARAMETER NOT 0
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
*         (PS,PD,EL)= 
* 
* 
 PRC.4    BSS    0
          RJ     NEXTP
          SA2    ZERO 
          BX2    X2-X6
          ZR     X2,ERROR    PARAMETER IS 0 
          SB2    B5-PDOPTION
          JP     PRC.41+B2
* 
* 
 PRC.41   BSS    0
+         EQ     PRC.4PD
+         EQ     PRC.4PS
+         EQ     PRC.4EL
* 
* 
 PRC.4PD  BSS    0
          SA2    SIX
          BX2    X2-X6
          NZ     X2,PRC.PD1 
          SA2    PD6         PDOPTION IS 6
          EQ     PRC.PD2
* 
* 
 PRC.PD1  BSS    0
          SA2    EIGHT
          BX2    X2-X6
          NZ     X2,ERROR    ILLEGAL PD PARAMETER 
          SA2    PD8         PDOPTION IS 8
 PRC.PD2  BSS    0
          BX3    X6 
          BX6    X2 
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
 PRC.4PS  BSS    0
          BX1    X6 
          SX6    B0 
 PRC.PS1  BSS    0
          LX1    6
          BX2    X5*X1       GET DIGIT
          ZR     X2,PRC.PS2  END OF LOOP
          SX2    X2-1R0 
          NG     X2,ERROR    BAD DIGIT (.LT. 0) 
          SX3    X2-10
          PL     X3,ERROR    BAD DIGIT (.GE. 10)
          LX6    1           *2 
          BX3    X6 
          LX6    2           *8 
          IX3    X6+X3       *10
          IX6    X3+X2
          EQ     PRC.PS1
* 
* 
 PRC.PS2  BSS    0
          SX1    X6-4 
          NG     X1,ERROR    PS MUST BE .GE. 4
          SX1    X6-PSMAX 
          PL     X1,ERROR    PS MUST BE .LT. 32768
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
 PRC.4EL  BSS    0
          SA2    FATAL
          BX2    X2-X6
          ZR     X2,PRC.EL1 
          SA2    WARNING
          BX2    X2-X6
          NZ     X2,ERROR    NOT F OR W 
          SX6    B0 
 PRC.EL1  BSS    0
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
 PRC.5    BSS    0           (TR)=(UP TO 3 OCTAL DIGITS)
          RJ     NEXTP       GET NEXT PARAMETER 
          LX1    6           GET 3 OCTAL DIGITS FROM TROPTION 
          BX6    X5*X1
          SX6    X6-1R0 
          MX3    57 
          BX2    X3*X6
          NZ     X2,ERROR    DIGIT NOT OCTAL
          LX1    6
          BX2    X5*X1
          LX6    3
+         ZR     X2,*+1 
          SX2    X2-1R0 
          BX6    X2+X6
          BX2    X2*X3
          NZ     X2,ERROR    DIGIT NOT OCTAL
          LX1    6
          BX2    X5*X1
          LX6    3
+         ZR     X2,*+1 
          SX2    X2-1R0 
          BX6    X6+X2
          BX2    X2*X3
          NZ     X2,ERROR    DIGIT NOT OCTAL
          LX6    51 
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
 PRC.6    BSS    0           (GO)=(0) 
          RJ     NEXTP
          SA2    ZERO 
          BX2    X2-X6
          NZ     X2,ERROR    PARAMETER NOT ZERO 
          MX6    59          -1 
          SA6    OPOUT+B5 
          EQ     NEXT 
* 
* 
* 
 PRC.7    BSS    0           (LO)=(S/L/0) 
          RJ     NEXTP       GET NEXT PARAMETER 
          SB3    SLOPTION 
          SA2    SOURCE 
          BX2    X2-X6
          ZR     X2,PRC.71   PARAMETER IS S 
          SB3    OLOPTION 
          SA2    OBJECT 
          BX2    X2-X6
          ZR     X2,PRC.71   PARAMETER IS O 
          SA2    ZERO 
          BX2    X2-X6
          ZR     X2,PRC.72   PARAMETER IS 0 
          EQ     ERROR       ILLEGAL LIST OPTION
* 
* 
 PRC.71   BSS    0
          SA6    OPOUT+B3    MAKE OPOUT NON ZERO
          SB3    B2-TSLSH 
          ZR     B3,PRC.7    SEPARATOR IS / 
          SB3    B2-KSLSH 
          ZR     B3,PRC.7 
          EQ     NEXT 
* 
* 
 PRC.72   BSS    0
          SX6    B0 
          SA6    OPOUT+SLOPTION        ZERO OUT SLOPTION
          SA6    A6+B1         AND OLOPTION 
          SB3    B2-TSLSH 
          ZR     B3,PRC.7    SEPARATOR IS / 
          SB3    B2-KSLSH 
          ZR     B3,PRC.7 
          EQ     NEXT 
* 
* 
* 
 PRC.8    BSS    0                 (DB) = (B/DL/ID/TR/0)
          SA2    OPDEFT+B5         SELECT DB=B/DL/ID DEFAULT LIST 
          BX7    X2 
 PRC.80   BSS    0
          RJ     NEXTP       GET NEXT PARAMETER 
          MX2    1
          SA3    TRC
          BX3    X3-X6       IS PARAMETER = TR
          NZ     X3,PRC.81         BR, NOT TR 
          AX2    1
          BX7    X7+X2       YES, IT IS. SET BITS 59 AND 58 
          EQ     PRC.85 
* 
* 
* 
*     PROCESS DEBUG PARAMETERS. THE RULES ARE:  
* 
*      (A) DB=0     TURNS OFF GENERATION OF CID INFORMATION 
*                   BIT 55 OF DBOPTION IS SET FOR THIS CONDITION
* 
*      (B) DB=ID    WILL FORCE B=ZZZZZDC AND GO ONLY IN THE 
*                   COMPILE-TO-CORE CASE WHEN B AND GO ARE
*                   NOT EXPLICITLY SET BY USER
* 
*      (C) BIT 56 OF DBOPTION ENABLES INETRACTIVE DEBUG 
* 
*      (D) USER SET B AND GO PARAMETERS ARE ALWAYS HONORED
* 
 PRC.81   BSS    0
          SA3    ID 
          BX3    X3-X6             IS PARAMETER = ID
          NZ     X3,PRC.82         BR, NOT ID 
          LX2    57 
          BX7    X7+X2             SET BIT 56 
          MX2    4
          BX7    X7*X2             CLEAR BIT 55 
          EQ     PRC.85 
 PRC.82   BSS    0
          SA3    DL 
          BX3    X3-X6       IS PARAMETER = DL
          NZ     X3,PRC.83   PARAMETER IS NOT DL
          BX7    X7+X2       YES, SET BIT 59
          EQ     PRC.85 
* 
* 
 PRC.83   BSS    0
          SA3    B
          BX3    X3-X6
          NZ     X3,PRC.84   PARAMETER IS NOT B 
          LX2    58 
          BX7    X7+X2       SET BIT 57 
          EQ     PRC.85 
* 
* 
 PRC.84   BSS    0
          SA3    ZERO 
          BX3    X3-X6
          NZ     X3,ERROR    PARAMETER IS NOT ZERO
          MX7    1
          LX7    56                SET BIT 55 
 PRC.85   BSS    0
          SB3    B2-TSLSH 
          ZR     B3,PRC.80         BR, SEPARATOR IS / 
          SB3    B2-KSLSH 
          ZR     B3,PRC.81
          SA7    OPOUT+B5 
          SX7    B0          CLEAR X7 FOR POSSIBLE USE IN OTHER ROUTINES
          EQ     NEXT 
* 
* 
* 
 NEXTP    BSSZ   1
          SA1    A1+B1       NEXT PARAMETER 
          SB7    B7-B1       PARAMETER COUNT - 1
          BX6    X1*X4
          SB2    X1 
          SB3    B2-TEQU
          ZR     B3,ERROR    SEPARATOR MUST NOT BE =
          SB3    B2-KEQU
          ZR     B3,ERROR 
          EQ     NEXTP
* 
* 
* 
 ERROR    BSS    0
          MESSAGE PARERR,0,R
          JP     EXITOUT     BR TO ABORT
FILERR    BSS    0
          MESSAGE LFNERR,0,R FIRST CHARACTER NOT ALPHA
EXITOUT   BSS    0
          IFC    EQ,,"OS.NAME",KRONOS,
          ABORT 
          ELSE
          ABORT  ,ND
          ENDIF 
* 
* 
* 
 ENDCHR   BSS    0           END OF OPTIONS 
          SA1    OPOUT+LOPTION
          NZ     X1,END1     LOPTION SPECIFIED
          SA1    OPTABLE+TROPTION 
          LX1    41 
          NG     X1,END4     TROPTION SPECIFIED 
          BX6    X6-X6       NO L OR TR OPTION
          SA6    OPOUT+SLOPTION 
          SA6    OPOUT+OLOPTION 
          SA6    OPOUT+LOPTION
          EQ     END6 
* 
 END1     BSS    0
          SA1    OPOUT+LOPTION
          BX6    X1 
          SA1    OPOUT+SLOPTION 
          SA2    OPTABLE+ENDOFOPT+1 
          LX2    41 
          PL     X2,END11    LOOPTION NOT SPECIFIED 
          ZR     X1,END2     NO SLOPTION
 END11    BSS    0
          SA6    A1 
 END2     BSS    0
          SA1    OPOUT+OLOPTION 
          ZR     X1,END3     NO OLOPTION
          SA6    A1 
 END3     BSS    0
          SA1    OPTABLE+EOPTION
          LX1    41 
          NG     X1,END5     EOPTION SPECIFIED
          SA6    OPOUT+EOPTION
          EQ     END5 
* 
 END4     BSS    0           TR OPTION WITHOUT L OPTION 
          SA1    =L*OUTPUT* 
          BX6    X1 
          SA6    OPOUT+LOPTION         FORCE L AND SLOPTION = OUTPUT
          SA6    OPOUT+SLOPTION 
          SX6    B0 
          SA6    OPOUT+OLOPTION 
 END5     BSS    0
          SA1    OPOUT+SLOPTION        IF NO SL 
          SA2    OPOUT+OLOPTION          AND OL 
          BX6    X1+X2
          NZ     X6,END6         THEN 
          SA6    OPOUT+LOPTION  LOPTION = 0 
 END6     BSS    0
          SA1    OPOUT+GOOPTION 
          NZ     X1,END7     GOOPTION SPECIFIED 
          SA2    OPOUT+XOPTION  IF GO OMITTED 
          ZR     X2,END7          AND XOPTION SPECIFIED 
          BX7    -X1                THEN GOOPTION = -0
          SA7    A1 
 END7     BSS    0
          SA1    OPOUT+DBOPTION 
          LX1    3
          PL     X1,END8           BR, NO INTERACTIVE DEBUG 
          SA1    OPOUT+XOPTION     CHECK FOR B OPTION 
          NZ     X1,END8           BR, USER SELECTED B OPTION 
          SA1    BINDEFT           FORCE B=ZZZZZDC
          BX6    X1 
          SA6    OPOUT+XOPTION     FORCE B OPTION 
          SA1    OPOUT+GOOPTION    CHECK FOR GO OPTION
          NZ     X1,END8           BR, USER SELECTED GO OPTION
          SA1    OPDEFT+GOOPTION   GET GO OPTION DEFAULT
          BX6    X1 
          SA6    OPOUT+GOOPTION    FORCE GO OPTION
* 
 END8     BSS    0
          SA1    OPOUT+LOPTION   GET THE L OPTION 
          ZR     X1,END8A    BRANCH IF NOT SET
          SA2    OPOUT+IOPTION
          IX2    X2-X1       SEE IF L=I 
          ZR     X2,END8X    YES, ERROR 
          SA2    OPOUT+XOPTION
          IX2    X2-X1       SEE IF L=B 
          ZR     X2,END8X    YES, ERROR 
 END8A    SA1    OPOUT+EOPTION   GET THE E OPTION 
          ZR     X1,END8C    BRANCH IF NOT SET
          SA2    OPOUT+IOPTION
          IX2    X2-X1       SEE IF E=I 
          ZR     X2,END8X    YES, ERROR 
          SA2    OPOUT+XOPTION
          IX2    X2-X1       SEE IF E=B 
          ZR     X2,END8X    YES, ERROR 
 END8C    SA1    OPOUT+XOPTION   GET THE B OPTION 
          ZR     X1,END8B 
          SA2    OPOUT+IOPTION
          IX2    X2-X1       CHECK IF I=B 
          ZR     X2,END8X   YES, ERROR
 END8B    BSS    0
          SX6    B0 
          SB6    B6-B1       ENDOFOPT 
          SA1    OPOUT
          SA6    B0 
 MOVE     BSS    0           NOW MOVE OPOUT TO LOW CORE 
          ZR     B6,ENDMOVE 
          SB6    B6-B1
          SA1    A1+B1
          BX6    X1 
          SA6    A6+B1
          EQ     MOVE 
* 
 ENDMOVE  BSS    0
         EQ        BASCARD
 END8X    MESSAGE CONERR,0,R
          IFC    EQ,,"OS.NAME",KRONOS,
          ABORT 
          ELSE
          ABORT  ,ND
          ENDIF 
*         END CONTROL-CARD
* 
* 
          EJECT 
**********************************************************************
**                                                                   *
*                                                                    *
*         PARAMETERS FOR THE FOLLOWING MACROS ARE:                   *
*                                                                    *
*         OPTION =  OPTION NAME                                      *
*         OP     =  1,2 OR 3 CHARACTER OPTION CODE                   *
*         ACTION =  ACTION FOR THIS OPTION                           *
*         P1     =  VALUES IF OPTION NOT SPECIFIED                   *
*         P2     =  VALUES IF OPTION SPECIFIED WITHOUT PARAMETERS    *
*                                                                    *
**********************************************************************
* 
 OPTBL    MACRO  OPTION,OP,ACTION,P1,P2 
          ORG    OPTABLE+OPTION 
          VFD    42/0L_OP,18/ACTION 
          ORG    OPOUT+OPTION 
          VFD    60/0L_P1 
          ORG    OPDEFT+OPTION
          VFD    60/0L_P2 
          ENDM
* 
 OPTBL1   MACRO  OPTION,OP,ACTION,P1,P2 
          ORG    OPTABLE+OPTION 
          VFD    42/0L_OP,18/ACTION 
          ORG    OPOUT+OPTION 
          VFD    60/P1
          ORG    OPDEFT+OPTION
          VFD    60/P2
          ENDM
* 
* 
 OPTABLE  BSSZ   2                 OPTION CODES AND ACTIONS 
          USE    1
 OPOUT    BSSZ   2                 FIRST DEFAULTS 
          USE    2
 OPDEFT   BSSZ   2                 SECOND DEFAULTS
          OPTBL  0,,ERROR,OUTPUT,OUTPUT 
          OPTBL  EOPTION,E,PRC.2,OUTPUT,ERRS
          OPTBL  IOPTION,I,PRC.2,INPUT,COMPILE
          OPTBL  XOPTION,B,PRC.2,,BIN 
          OPTBL1 ASOPTION,AS,PRC.3,IP.AS,1
          OPTBL  LOPTION,L,PRC.2,OUTPUT,OUTPUT
          OPTBL  SLOPTION,,ERROR,OUTPUT,OUTPUT
          OPTBL  OLOPTION,,ERROR,,OUTPUT
          OPTBL1 BLOPTION,BL,PRC.3,IP.BL,1
          OPTBL1 TROPTION,TRC,PRC.5,,77700000000000000000B
          OPTBL1 DBOPTION,DB,PRC.8,,50000000000000000000B 
          OPTBL  PDOPTION,PD,PRC.4,S,T    (PD=6 THEN 1LS, PD=8 THEN 1LT)
          OPTBL1 PSOPTION,PS,PRC.4
          OPTBL  ELOPTION,EL,PRC.4        (EL=F THEN F) 
          OPTBL1 GOOPTION,GO,PRC.6,,1     (GO=0 THEN -1)
          OPTBL  KOPTION,K,PRC.2,OUTPUT,OUTPUT
          OPTBL  JOPTION,J,PRC.2,INPUT,INPUT
          OPTBL  ENDOFOPT+1,LO,PRC.7
          ORG    OPDEFT+ENDOFOPT+2
 TEQU     EQU     2          SCOPE =
 KEQU     EQU    54B         KRONOS = 
 TSLSH    EQU     3          SCOPE /
 KSLSH    EQU    50B         KRONOS / 
 ZERO     DATA   0L0
 SIX      DATA   0L6
 EIGHT    DATA   0L8
 FATAL    DATA   0LF
 WARNING  DATA   0LW
 SOURCE   DATA   0LS
 OBJECT   DATA   0LO
 DL       DATA   0LDL        FOR DBOPTION 
 TRC      DATA   0LTR        FOR DBOPTION 
 B        DATA   0LB         FOR DBOPTION 
 ID       DATA   0LID              INTERACTIVE DEBUG OPTION 
 BINDEFT  VFD    60/0L_ZZZZZDC     B OPTION FOR COMPILE-TO-CORE 
 PD6      EQU    SOURCE 
 PSMAX    EQU    100001B     PS MAX LIMIT .LE. 32768
 PD8      DATA   0LT
 IBSW     DATA   L*BASIC$*
STAT      BSS    1                                                       BAS0014
 PGSIZE   BSSZ   2           PAGE SIZE PARAMETER BLOCK
* 
* 
* 
* 
* 
* 
* 
LFNERR    DATA   C* ILLEGAL FILE NAME- *
          DATA   0
 PARERR   DATA   C*  BAD CONTROL CARD ARGUMENT - *
          DATA   0
 CONERR   DATA   C*  CONTROL CARD FILENAME CONFLICT * 
          EJECT 
* 
          IFC    EQ,,"OS.NAME",SCOPE ,
*                THE FOLLOWING DATA IS USED FOR PP CALLS IN SCOPE 
ADRRWE    DATA   0
          ENDIF 
* 
          END 
