*COMDECK /SCANDR/ 
 TA       SET       6 
 TB       SET       4 
 TC       SET       7 
 TD       SET       3 
 TE       SET       5 
 TMP      SET       1 
 HERE     SET       3 
 STOPAT   SET       4 
 BT       SET       5 
 SCR$SQ   BSS       0 
* 
*     RECORD MARK SCAN
* 
*     INPUT --- 
*          B3 - BEGINNING OF RECORD 
*         A3=B3 
*         X3 - FIRST WORD OF RECORD 
*         B5 - BBT
*          B6 - RETURN ADDRESS
*     USES ---
*          X023457
*          A34
*          B23456 
*     OUTPUT ---
*          X2 - NO. OF CHARACTERS FOUND 
*          X4 LT 0 IFF NO RMK FOUND 
          F.RM      RMK,TB,X.TA    SAY RMK IS]
          BX.TB    X.TA            SET UP 10H]]]]]]]]]] 
          LX.TA    6
          BX.TB    X.TA+X.TB
          BX.TA    X.TB 
          LX.TB    12 
          BX.TA    X.TA+X.TB
          LX.TB    12 
          BX.TB    X.TA+X.TB
          LX.TA    36 
          BX.TA    X.TA+X.TB
* THE ABOVE ASSUMES 6-BIT CHAR. 
  
          SB2       X2             SAVE FOR COMPUTATION LATER 
          SA.TB    AAAAA           MAGIC NUMBER 
          SB.BT     10
          EQ       RLOOP
  
*-----LOOP
 RSHTCUT  BSS    0
          SA.TD     A.TD+B1        LOAD NEXT WORD 
          SB2       B2-B.BT 
          LE        B2,RGOREAD     EXIT LOOP
 RLOOP    BSS      0               NEXT 4 INST. WORK BY MAGIC...
          BX.TC  X.TD-X.TA
          IX.TMP    X.TC-X.TB 
          BX.TE     -X.TMP-X.TC 
          BX.TE    X.TE*X.TB
          ZR       X.TE,RSHTCUT    TAKE A SHORTCUT IF NO ]
*-----END LOOP
  
          SX.TMP    B2
          IX2       X2-X.TMP
          MX.TE    54 
          SB.BT     B0
          BX.TC  -X.TE*X.TA        GET RMK
          LX.TD    6               GET CHAR OF LAST WORD
 MRLOOP   BSS      0               SEARCH WORD FOR RMK
          BX.TB    -X.TE*X.TD 
          LX.TD    6
          IX.TB  X.TB-X.TC
          SB.BT  B.BT+B1           COUNT UP BCC 
          NZ       X.TB,MRLOOP     JUMB IF NOT RMK
          SX2    X2+B.BT           NUMBER OF CHARACTERS FOUND 
          MX4    0                 = RMK FOUND
          JP     B6                RETURN 
 RGOREAD  BSS      0
          SX.TMP    B2
          IX2       X2-X.TMP       NUMBER OF CHAR SCANNED 
          MX4    1                 = RMK NOT FOUND
          JP     B6                RETURN 
