*DECK RMDSYSE 
          IDENT     RM$SYS=        POST RA+1 REQUEST
          COMMENT   CRM - POST RA+1 REQUEST 
          ENTRY     RM$SYS= 
*#
*1CD  RM$SYS= 
*0D   PURPOSE 
*0        POST RA+1 REQUEST 
*0D   CALL
*0        RJ        =XRM$SYS= 
*0D   PARAMETERS
*0        A0        FET ADDRESS 
*         B1        1 
*         X7        RA+1 REQUEST PROPERLY FORMATTED 
*0D   ACTION
*0        FIRST WAIT FOR RA+1 TO CLEAR ANY PREVIOUS REQUEST, THEN STORE 
*         THE CURRENT REQUEST INTO RA+1.  NOW WE EITHER WAIT FOR THE
*         REQUEST TO BE PICKED UP (RA+1 CLEAR) OR ISSUE AN XJ, EXIT.
*0        CRM SUPPORTS TWO EDITIONS OF THIS ROUTINE.  THIS IS THE ONE 
*         FOR THE NORMAL CASE.   IN A TAF ENVIRONMENT LDSET(SUBST) IS 
*         USED TO INVOKE RM$TSYS INSTEAD.  OPEN$RM WILL CHANGE THE WORD 
*         AT *XJPLUG* IF XJ HARDWARE IS AVAILABLE.  SINCE THIS WORD IS
*         AT A DIFFERENT LOCATION RELATIVE TO THE ENTRY POINT ACCROSS 
*         THE TWO EDITIONS, THE LOWER HALF OF THE ENTRY POINT WORD WILL 
*         CONTAIN ITS ADDRESS.
*0D   REGISTERS USED
*0        A17,X17 
*0D   OTHER CODE REQUIRED 
*0        PROGRAMS- NONE
*         MACROS-   NONE
*#
 RM.SYS1  BSS       0 
          SX1       B1
          PX1       X1
          FX1       X1/X1          REDUCE PYRAMID CLUTTER 
          FX1       X1/X1 
 XJPLUG   BSS       0              ****** OPEN MAY PLANT XJ HERE ****** 
          SA1       B1
          LX1       60-41 
          MI        X1,RM.SYS1     LOOP UNTIL AUTO-RECALL REQUEST TAKEN.
 RM$SYS=  EQ        *+1S17         --- ENTRY / EXIT --- 
 -        VFD       12/0,18/XJPLUG LOCATION TO RECEIVE XJ INSTRUCTION 
 WAIT     BSS       0 
          SA1       B1
          NZ        X1,WAIT        IF PREVIOUS REQUEST NOT TAKEN
          SA7       B1             POST REQUEST 
          EQ        XJPLUG         GO WAIT RA+1 CLEAR  OR  ISSUE XJ 
          END 
