*DECK SSISURP 
          IDENT  SSISURP
*CALL COPYRITE
          ENTRY  SSISURP
          SST 
          SYSCOM B1 
 OPL      XTEXT  COMSRPV
          B1=1
          TITLE  SSISURP - SETUP REPRIEVE PROCESSING. 
          COMMENT  SSISURP - SETUP REPRIEVE PROCESSING. 
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS, INC. 1994.
          SPACE  4,10 
**        SSISURP - SETUP REPRIEVE PROCESSING.
* 
*         SSISURP 
* 
*         ENTRY  INITIALIZATION CALL (ENTRY POINT IS SSISURP):  
*                  NONE.
*                REPRIEVE TRANSFER (ENTRY POINT IS SSIRPV): 
*                  NONE.
* 
*         EXIT   INITIALIZATION CALL (ENTRY POINT IS SSISURP):  
*                  THE MESSAGE MACRO HAS BEEN CALLED TO ISSUE A DAYFILE 
*                  MESSAGE CONTAINING THE BUILD DATE AND TIME.
*                  REPRIEVE (SETUP TYPE) HAS BEEN CALLED TO REPRIEVE
*                  ALL CONDITIONS EXCEPT NORMAL TERMINATION.
* 
*                ABNORMAL TERMINATION TRANSFER (ENTRY POINT IS SSIRPV): 
*                  FILE ZZZZDMB IS CREATED AND CONTAINS THE BINARY DUMP.
*                  A NETOFF IS ISSUED TO NAM. 
*                  REPRIEVE IS CALLED TO RESET THE ERROR CONDITION AND
*                  CONTROL IS RETURNED TO THE OPERATING SYSTEM. 
* 
*         MACROS REPRIEVE, MESSAGE. 
          SPACE  4,10 
          USE    /ACBUILD/             BUILD DATE AND TIME
 BLDMSG   DIS    ,*ATF-BUILT"DATE""TIME"* 
          USE    *
  
          USE    /NETINIT/             SCSF CONNECTED TO NETWORK
 NETINIT  VFD    60/0 
          USE    *
  
 RPVMSG   DIS    ,*ATF-REPRIEVED* 
  
 RPVPRM   VFD    48/25,12/0            REPRIEVE PARAMETER BLOCK 
          VFD    60/SSIRPV             REPRIEVE TRANSFER ADDRESS
          BSSZ   23D
  
 SYS$EQ   BSS    1                     CONTENTS OF SYS EQUALS 
  
          EJECT 
 SSISURP  SUBR                         ENTRY/EXIT FOR INITIALIZATION
  
          MESSAGE   BLDMSG,0,R         DAYFILE BUILD DATE AND TIME
  
          REPRIEVE  RPVPRM,SETUP,277B  INITIALIZE REPRIEVE PROCESSING 
          EQ     SSISURPX 
  
 SSIRPV   BSS    0                     REPRIEVE TRANSFER ADDRESS
          SB1    1
          SA1    =XSYS= 
          BX6    X1                    SAVE LAST CALL TO SYS EQUALS 
          SA6    SYS$EQ 
          MESSAGE   RPVMSG,0,R         DAYFILE REPRIEVE PROCESSING
  
          SYSTEM DMB,R
  
          SA2    NETINIT
          ZR     X2,SSIRPV1            NOT NETTED ON
  
          RJ     =XNETOFF              NETOFF 
  
 SSIRPV1  SB1    1                     RESTORE (B1) TO ONE
  
          REPRIEVE  RPVPRM,RESET,277B  RESET ERROR WITH NO RETURN 
  
          END 
