*DECK SSISRID 
USETEXT TEXTATS 
USETEXT TEXTRPC 
USETEXT TEXTXDR 
      PROC SSISRID (IDTYPE, LENGTH, POSITION);
*CALL COPYRITE
# TITLE SSISRID - SKIP RESPONSE IDENTIFIER.                            #
  
      BEGIN                            # SSISRID                       #
# 
****  SSISRID - SKIP RESPONSE IDENTIFIER. 
* 
*     THIS PROCEDURE UPDATES THE BUFFER POSITIONING IN *INDATABUF* TO 
*     SKIP OVER THE RESPONSE IDENTIFIER FIELD.
* 
*     PROC SSISRID
* 
*     ENTRY    IDTYPE   = IDENTIFIER TYPE 
*              LENGTH   = NUMBER OF BYTE REMAINING IN *INDATABUF* 
*              POSITION = CURRENT POSITION IN *INDATABUF* 
* 
*     EXIT     LENGTH   = NUMBER OF BYTE REMAINING IN *INDATABUF* 
*              POSITION = UPDATED POSITION IN *INDATABUF* 
* 
*     METHOD   BASED ON THE RESPONSE IDENTIFIER, SKIP THE APPROPRIATE 
*              NUMBER OF BYTES IN *INDATABUF*.  UPDATE THE NUMBER OF
*              ITEMS REMAINING IN *INDATABUF*.
# 
  
      ITEM IDTYPE              I;      # IDENTIFIER TYPE INPUTTED      #
      ITEM LENGTH              I;      # REMAINING BUFFER LENGTH       #
      ITEM POSITION            I;      # CURRENT BYTE LOCATION IN BUF  #
  
      ITEM SKIP                I;      # SKIP LENGTH IN BYTES          #
CONTROL EJECT;
  
# 
****  START MAIN PROCEDURE
# 
  
      SKIP = 0; 
  
      IF IDTYPE EQ ATSID$ 
      THEN                             # AUTOMATED CARTRIDGE SYSTEM    #
        SKIP = ATSLENGTH$;
  
      ELSE IF IDTYPE EQ CAPID$
      THEN                             # CARTRIDGE ACCESS PORT         #
        SKIP = CAPLENGTH$;
  
      ELSE IF IDTYPE EQ CELLID$ 
      THEN                             # CARTRIDGE LOCATION IN LSM     #
        SKIP = CELLLENGTH$; 
  
      ELSE IF IDTYPE EQ DRIVEID$
      THEN                             # CARTRIDGE DRIVE               #
        SKIP = DRIVELENGTH$;
  
      ELSE IF IDTYPE EQ LSMID$
      THEN                             # LIBRARY STORAGE MODULE        #
        SKIP = LSMLENGTH$;
  
      ELSE IF IDTYPE EQ NONEID$ 
      THEN                             # ID TO BE IGNORED (NONE)       #
        SKIP = NONELENGTH$; 
  
      ELSE IF IDTYPE EQ PANELID$
      THEN                             # STORAGE AREA WITHIN LSM       #
        SKIP = PANELLENGTH$;
  
      ELSE IF IDTYPE EQ PORTID$ 
      THEN                             # COMM LINE BETWEEN THEN LMU AND#
        SKIP = PORTLENGTH$;            # SERVER SYSTEM                 #
  
      ELSE IF IDTYPE EQ SUBID$
      THEN                             # LOGICAL DIVISION OF PANEL     #
        SKIP = SUBLENGTH$;
  
      ELSE IF IDTYPE EQ VOLID$
      THEN                             # TAPE VSN                      #
        SKIP = VOLLENGTH$;
  
      SKIP = (SKIP + RSPSKIP$) * 4; 
      POSITION = POSITION + SKIP;      # SKIP RESPONSE BYTES IN BUFFER #
      LENGTH = LENGTH - SKIP;          # UPDATE REMAINING BUFFER LNGTH #
  
      END                              # SSISRID                       #
  
      TERM
*WEOR 
