*COMDECK /EXECOM/                                                        /EXECOM
 EXEC     BSS    0                                                       /EXECOM
          BSSZ   1                                                       /EXECOM
          F.RM   MKL,3                                                   /EXECOM
          SF.AA  GCOM$AA,MKEYLNG,X3                                      /EXECOM
          SET.RM MKL,0       CLEAR MKL IN FIT                            /EXECOM
          F.RM   COP,B4,-#CLS#     OPEN AND CLOSE IS TAKEN CARE OF       /EXECOM
          SB1    1                                                       /EXECOM
          SB5    JWORD-JTAB                                              /EXECOM
          LT     B4,B1,*+1S17                                            /EXECOM
          GT     B4,B5,*+1S17                                            /EXECOM
          SA5    B4+JTAB-1                                               /EXECOM
          BX6    X5                                                      /EXECOM
          SA6    JWORD                                                   /EXECOM
          SX6    B4-#PUT#+#CLS#    TEST FOR PUT                          /EXECOM
          ZR     X6,CLRSTAK  THIS IS A PUT
          SF.AA  FIAT$AA,FACREAT,0  ELSE CLEAR THE CREATE FLAG           /EXECOM
 CLRSTAK  RJ     JWORD-1     GO JWORD,CLEARING INST STACK 
JTAB      BSS    0                                                       /EXECOM
*                                                                        /EXECOM
*                                                                        /EXECOM
          XI     GET,0                                                   /EXECOM
          XI     GETN,0                                                  /EXECOM
          XI     PUT,1                                                   /EXECOM
          XI     SEEK,0                                                  /EXECOM
          XI     GTNR,0                                                  /EXECOM
          XI     DLT,1                                                   /EXECOM
          XI     REPL,1                                                  /EXECOM
          XI     REW,0                                                   /EXECOM
          XI     STFT,0                                                  /EXECOM
          XI     SKIP,0                                                  /EXECOM
          XI     SKIP,0                                                  /EXECOM
* BOTH FORWARD AND BACKWARD SKIP                                         /EXECOM
          XI     GET,0                                                   /EXECOM
*                                                                        /EXECOM
*#                                                                       /EXECOM
*         RETURNING FROM THE JWORD CALL, THE LOW ORDER BIT OF JWORD IS   /EXECOM
*         SET IF LAST OP IS AN UPDATE. THE MOD IN PROGRESS FLAG(S), SET  /EXECOM
*         WHILE WE ARE DOING UPDATES, ARE CLEARED BEFORE WE EXIT TO      /EXECOM
*         SIGNIFY THAT THE UPDATE IS COMPLETED.  IF THE FORCE WRITE      /EXECOM
*         INDICATOR IS ON FOR THAT USER FIT, WE WILL SET UP TO FLUSH     /EXECOM
*         THAT FILE.  FWIFLG IS SET IN GCOM TO TELL FLUSH NOT TO EXTEND  /EXECOM
*         THE FILE AFTER FLUSH, AS EVERY EXTEND WILL RESULT IN           /EXECOM
*         ONE DAYFILE MESSAGE, WHICH IS UNDESIRABLE.  WE THEN CLEAR THE  /EXECOM
*         FLAG, AND EXIT.                                                /EXECOM
*#                                                                       /EXECOM
          BSS    1                 RESERVED SPACE FOR PSUEDO RJ          /EXECOM
JWORD     RJ     *+1S17                                                  /EXECOM
          SA1    JWORD                                                   /EXECOM
          SX6    B0                                                      /EXECOM
          LX1    59                                                      /EXECOM
          SA6    BLOK$AA                                                 /EXECOM
          PL     X1,EXEC                                                 /EXECOM
*                                                                        /EXECOM
          SA2    FSTT$AA                                                 /EXECOM
          SF.AA  X2,FSMODFL,0      CLEAR MOD IN PROGRESS FLAG            /EXECOM
          RF.AA  X2,FSMIPFS,3      FOR DATA FILE                         /EXECOM
          ZR     X3,FWRITE   AND/OR                                      /EXECOM
          SF.AA  X3,FSMODFL,0      MIP FILE                              /EXECOM
 FWRITE   SA2    FIT$AA                                                  /EXECOM
          SA0    X2                                                      /EXECOM
          SA2    A0                                                      /EXECOM
          OFF.RM FWI,EXEC    EXIT IF FWI IS OFF                          /EXECOM
          MX0    42                                                      /EXECOM
          SX1    A0                                                      /EXECOM
          BX0    X2*X0       ISOLATE LFN                                 /EXECOM
          IX6    X0+X1       OR IN FIT ADDRESS                           /EXECOM
          SA6    PAR                                                     /EXECOM
*         NOTE THAT PAR+1 MUST BE 0                                      /EXECOM
          SF.AA  GCOM$AA,FWIFLG,1  SET GLOBAL FWI FLAG TO TELL FLUSH     /EXECOM
          SA1    PLIST                                                   /EXECOM
          RJ     =YFLSH$AA   FLUSH THE FILE,NO EXTEND                    /EXECOM
          SF.AA  GCOM$AA,FWIFLG,0  CLEAN FWI FLAG                        /EXECOM
          EQ     EXEC                                                    /EXECOM
 PLIST    VFD    42/0,18/*+1                                             /EXECOM
          VFD    42/0,18/*+1                                             /EXECOM
 PAR      BSSZ   2                                                       /EXECOM
*         PAR + 1 MUST ALWAYS BE 0                                       /EXECOM
