*COMDECK  COMFSCS -     SCAN TABLE WITH SUPPLIED MASK 
 COMFSCS  CTEXT 
**        SCS - SCAN TABLE WITH SUPPLIED MASK.
* 
*         ENTRY  (A1) - TABLE TO BE SEARCHED
*                (X6) - ENTRY LOOKING FOR IN GIVEN TABLE
*                (SCSA) = MASK TO BE USED 
* 
*         EXIT   IF ENTRY *NIT* - (B7) IS NEGATIVE
*                                 (A1),(X1) PRESERVED 
*                                 (X6) UNTOUCHED
*                IF ENTRY *IT*  - (B7) ORDINAL OF MATCHING ENTRY
*                                 (X2) ALL 60 BITS OF MATCHING ENTRY
*                                 (A2) _ TO MATCHING ENTRY
*                                 (X6) = (X2) .AND. MASK
* 
*         USES   A2,A3,A6  X0,X1  B2,B7 
  
  
 SCS      SUBR   =           ...ENTRY/EXIT... 
          SA2    A1+=XN.TABLE 
          SA3    SCSA 
          SA6    X1-1        STORE CRITERION BELOW TABLE
          ERRMI  FUDGE-1     CODE REQUIRES 1 SLOP WORD
          SB7    A6 
          SA2    X2+B7       FETCH LAST ENTRY 
  
**        LOOP TILL MATCH FOUND 
  
 SCS1     BX0    X2-X6
          =A2    A2-1        FETCH NEXT TABLE ENTRY 
          NO
          BX0    X3*X0       MASK 
          NZ     X0,SCS1     IF NOT HIT - LOOP
  
          SB7    A2-B7       RELATIVE POSITION OF ENTRY 
          =A2    A2+1        TABLE ENTRY AT HIT 
          MI     B7,SCSX     IF DUMMY HIT - EXIT... 
          BX6    X3*X2       MASK OFF 
          EQ     SCSX        EXIT...
  
 SCSA     CONENT 0           MASK TO BE USED
          ENDX
