*COMDECK  COMFISA - ISSUE SAVE A0 OR RJ CPL. .
 ISA      CTEXT  COMFISA - ISSUE SAVE A0 OR RJ CPL. . 
**        ISA - ISSUE SAVE A0 CODE OR RJ CPL. 
* 
*         ENTRY  (X4) = SYMTAB ORDINAL OF ENTRY OR HEADER 
  
 ISA      SUBR   =
          SA2    =XCO.DBID
          ZR     X2,ISA05    IF DB=ID NOT SELECTED
          ISSUE  7461B       SX6 A1 
          SA1    =XS=SA1
          ISSUE  5160B,X1    SA6 SAVEA1.
  
 ISA05    SA2    =XN.EPL
          NZ     X2,ISA20    IF CPL. CALL NEEDED
  
 ISA15    SA1    =XN.FP 
          NZ     X1,ISA17    IF FP/S
          SA2    MOD
          MX0    -MO.CLIFL
          LX2    -MO.CLIFP
          BX2    -X0*X2 
          ZR     X2,EXIT.    IF NOT CHARACTER FUNCTION
  
 ISA17    ISSUE  7460B       SX6 A0 
          ISSUE  5401B       SA0 A1 
          SA1    =XS=TA0
          ISSUE  5160B,X1          SA6 TEMPA0.
          SA2    =XCO.DBID
          ZR     X2,EXIT.    RETURN IF DEBUG NOT ON 
          ISSUE  7460B       SX6    A0
          SA1    =XS=SA0
          ISSUE  5160B,X1    SA6    SAVEA0
          EQ     EXIT.
  
 ISA20    SA2    =X"O$"SYM
          LX5    B1,X4
          IX6    X4+X5
          =B7    X2+WB.W
          SA3    B7+X6
          MX0    -WB.PNTL 
          LX3    -WB.PNTP 
          BX6    -X0*X3 
          SA4    =X"O$"ENTP 
          ZR     X6,ISA15    IF NO FPS THIS ENTRY 
          IX4    X4+X6
          SA2    =XMOD
          MX0    -MO.CLIFL
          LX2    -MO.CLIFP
          BX2    -X0*X2 
          ZR     X2,ISA30    IF NOT CHAR FUNCTION 
  
          ISSUE  1061B       BX6 X1 
          =X1    1
          LX1    PB.BIASP-PB.TAGP 
          ISSUE  5011B,X1     SA1 A1+1
          SA1    =XS=GPL
          ISSUE  5160B,X1     SA6 GPL.
  
 ISA30    SA1    X4-1 
          MX6    -EH.BIASL
          LX1    -EH.BIASP
          BX3    -X6*X1 
          SA1    =XS=CP 
          LX3    PB.BIASP-PB.TAGP 
          BX4    X1+X3
          ISSUE  7060B       SX6 A0+
          SA1    =XS=GPL
          ISSUE  5100B,X1          SA0 GPL. 
          ISSUE  5130B,X4    SA3 CP.+BIAS[ENTP] 
          SA1    =XS=TA0
          ISSUE  5160B,X1          SA6 TEMPA0.
          SA1    =XS=CPL
          ISSUE  I.RJ3,X1          RJ CPL.
          SA2    =XCO.DBID
          ZR     X2,ISA35    IF DEBUG NOT ON
          ISSUE  7460B       SX6    A0
          SA1    =XS=SA0
          ISSUE  5160B,X1    SA6    SAVEA0
 ISA35    EQU    *
          MX6    1
          SA6    =XENTRJ     FLAG RJ ISSUED 
          EQ     EXIT.
 COMFISA  ENDX
