*COMDECK  COMFFEI - FRONT END INITIALIZATION. 
 FEI      CTEXT  COMFFEI - FRONT END INITIALIZATION.
  
  
*         IN FEC
          EXT    F.SYMIL,Z.SYMDB,Z.SYMIL,Z.SYMVP
  
*         IN FTN
          EXT    CO.ANSI,CO.MD,CO.DBSL,CO.LOR,CO.OPT,CO.LCM 
  
*         IN PEM
          EXT    ANSI.SW,MDER.SW
  
*         IN PUC
          EXT    TIMER,TIME1,ERRTYP,WO.LCM
 FEI      SPACE  4,10 
**        FEI - FRONT END INITIALIZATION. 
* 
*         PERFORMS OVERLAY INITIALIATION FOR FRONT-END. 
*         NEEDED BY (0,0), (1,0), AND (2,1).
*         OTHER CODE WILL BE FOUND IN FEC/PUP, FOR STRANGE REASONS. 
* 
*         RESET CHARACTER SUBSTRING ROUTINES TO NON-CHECKING FORM,
*         DEPENDING ON (CO.DBSL). 
  
  
 FEI      SUBR               ...ENTRY/EXIT... 
  
**        RESET PROGRAM UNIT START TIME 
  
          CALL   TIMER
          SA6    TIME1
          SX5    Z=SYM
          SX6    Z.SYMVP
          IX6    X6/X5
          SX1    F.SYMIL
          SA1    X1+Z.SYMVP+1 
          SX5    M.LOG
          SX3    N.TYPE      LOOP LIMIT 
          LX6    WB.BASEP 
 FEI10    SA1    A1+Z=SYM 
          BX1    X1+X5       FILL IN WB.MODE
          BX7    X1+X6       FILL IN WB.BASE
          SA7    A1 
          =X5    X5+1 
          IX2    X5-X3
          MI     X2,FEI10    IF NOT DONE
          SA3    CO.DBSL
          SB2    Z.SYMDB
          NZ     X3,FEI30    IF SUBSTRING LIMIT CHECKING ENABLED
          SX3    2R..-1R.&2RC.
          =X4    MF.LIB&MF.BEF
          LX3    WA.SYMP+2*6
          SB7    Z.SYMIL
          LX4    WC.FUNTP 
 FEI20    SA1    B2+F.SYMIL+WA.W
          SA2    A1-WA.W+WC.W 
          BX6    X3-X1       CHANGE (C.) INTO (.:)
          BX7    X4-X2       CHANGE (MF.LIB) INTO (MF.BEF)
          SB2    B2+Z=SYM 
          SA6    A1 
          SA7    A2 
          NE     B2,B7,FEI20 IF MORE ENTRIES TO CONVERT 
  
 FEI30    SA1    CO.ANSI
          SA2    ERRTYP 
          SA3    CO.MD
          =A4    A2+1 
          BX6    X1+X2
          BX7    X3+X4
          SA6    A2          SET ERROR LEVEL FOR ANSI DIAGNOSTICS 
          SA7    A4          SET ERROR LEVEL FOR MACHINE DEPENDENT DIAG.
          ZR     X1,FEI50    IF ANSI DIAGNOSTICS NOT DESIRED
          SA2    ANSI.SW
          LX2    30 
          BX7    X2 
          SA7    A2          ENABLE ANSI DIAGNOSTICS
          SX1    X1-EL=F
          NZ     X1,FEI50    IF ERROR LEVEL NOT FATAL 
          SA1    ERRTYP+EL=W
          SX2    EL=F 
          MX0    -18
          BX1    X0*X1       ERASE EL=W 
          BX6    X2+X1
          SA6    A1          REPLACE WITH EL=F
  
 FEI50    ZR     X3,FEI60    IF MACHINE DEPENDENT DIAG. NOT DESIRED 
          SA2    MDER.SW
          LX2    30 
          BX7    X2 
          SA7    A2          ENABLE MACHINE DEPENDENT DIAGNOSTICS 
  
 FEI60    BSS    0
          SA1    CO.OPT 
          SA2    CO.LCM 
          =X6    -1 
          ZR     X1,FEI70    IF OPT = 0 
          BX6    X2 
  
 FEI70    SA6    WO.LCM      FORCE LCM=G FOR OPT=0
          EQ     EXIT.
  
  
 COMFFEI  ENDX
