*DECK     INIT23 (2,3) OVERLAY INITIALIZATION 
          IDENT  INIT23 
 INIT23   SECT   (INITIALIZE REAR END OVERLAY.),INI23 
 INIT23   SPACE  4,10 
*         IN FTN
          EXT    CO.LOR,CO.SNAP,CP.NFLS,FV.LGO,F.LGO,F.PB,F.REF,IDPCHK
          EXT    SYS=,WNB=
  
*         IN IDP
          EXT    IDP=,IDP=USY,PTO,UKT=LNK 
  
*         IN PUC
          EXT    BASES,L.TABS,O.TABS,RPV=URP,SIZES,THRESH,WOF 
  
*         IN REC
          EXT    REC
  
*         IN RPV20
          EXT    RPV2N
  
*         IN RPV23
          EXT    RPV23
  
*         IN RSNAP
          EXT    UKT=RE 
  
*         IN UTILITY
          EXT    RPV= 
 INIT23   SPACE  4,10 
**        INIT23 - INITIALIZE REAR END OVERLAY. 
* 
*         ENTRY  THE (2,3) HAS JUST BEEN LOADED.
* 
*         EXIT   TO *REC* TO BEGIN ASSEMBLY AND MAP PROCESSING. 
  
 FTN23    BSSENT
  
*         LINK RPV TABLES.
  
          SX6    0
          SX7    RPV23       (X7) = FWA OF (2,3) RNA TABLE
          SA6    RPV2N       MARK END-OF-(2,0) RNA TABLE
          SA7    A6+1        STORE LINK TO (2,3) RNA TABLE
  
*         TURN ON REPRIEVE. 
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
          =X6    0
          SA6    RPV=URP     CLEAR USER REPRIEVE PROCESSING 
          SA1    RA.SSW      SENSE SWITCH WORD
          LX1    59-5-6      GET SWITCH 6 
          MI     X1,INI1     IF SWITCH 6 ON 
 .TEST    ENDIF 
  
          RPVON              TURN ON REPRIEVE 
  
*         CHECK FOR IDP BREAK REQUEST.
*         LINK (2,3) SPECIFIC IDP KEYWORDS TO ROOT LIST.
*         SEE *UKT=LNK* IN (2,0) DECK *IDP*.
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
 INI1     BSS    0
 #OS      IFNE   .OS,2
          SX6    UKT=RE 
          SA6    UKT=LNK
  
          SX6    =YUSY=RE    (X6) = ADDR OF IDP SYMBOL SEARCH SUBR
          SA6    IDP=USY
  
          CALL   IDPCHK      CHECK FOR IDP REQUEST
          PL     B7,INI2     IF IDP NOT REQUESTED 
 FTN23    BREAK 
 #OS      ENDIF 
 .TEST    ENDIF 
  
*         INITIALIZE OVERLAY. 
  
 INI2     SB3    FTN23       END OF CODE IN OVERLAY 
          SA2    CO.LOR      MASTER REFERENCE MAP FLAG
          PL     X2,INI3     IF NO MAP
          SETFIL FILE=F.REF,MODE=INIT,FWA=B3  SET MAP BUFFER
 INI3     SETFIL FILE=F.PB,MODE=INIT,FWA=B3   SET PB BUFFER 
          SA1    FV.LGO 
          SX6    B3 
          ZR     X1,INI3A    IF NO LGO
          SETFIL FILE=F.LGO,MODE=INIT,FWA=B3  SET LGO BUFFER
          SX6    B2          FWA OF LGO 
 INI3A    SA6    O.TABS      SET ORIGIN OF MANAGED TABLES 
          SA6    BASES       SET START OF FIRST TABLE 
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
          SA1    SIZES
          ZR     X1,INI4     IF FIRST TABLE EMPTY 
          PLINE  INIA,5 
          EQ     INI5        PRINT TABLE STATISTICS 
  
 INI4     SA1    CO.SNAP
          LX1    1RT
          PL     X1,INI6     IF NO SNAP DESIRED 
 INI5     PLINE  INIB,5 
          CALL   PTO         PRINT TABLE ORIGINS
 INI6     SA1    O.TABS 
          BX6    X1          RESTORE (X6) AFTER SNAPS 
 .TEST    ENDIF 
  
          SA2    CP.NFLS
          IX6    X2-X6
          SA6    L.TABS      SET SIZE OF TABLE AREA 
          AX6    FLSLOP 
          SA6    THRESH      GIVE ALLOC SOME ELBOW ROOM 
          EQ     REC         TRANSFER TO REAR END CONTROLLER... 
  
 .T       IFEQ   TEST,ON
 INIA     DIS    5,  -----    *         TRASHED TABLES NOT ALL EMPTY. 
 INIB     DIS    5,   TABLE STATISTICS ON ENTRY TO PASS THREE --
 .T       ENDIF 
  
  
  
  
          LIST   D
          ENTRY  B=LWA23
 B=LWA23  END                MARK LWA OF OVERLAY FOR RPV
