*DECK     INIT10             SECONDARY INITIALIZATION - AFTER COMPASS 
          IDENT  INIT10 
 INIT10   SECT   (REINITIALIZATION / AFTER COMPASS ASSEMBLY.) 
 INIT10   SPACE  4,8
*         IN FEC
          EXT    OSTACK 
  
*         IN FTN
          EXT    CO.ANSI,CO.LOA,CO.LOO,CO.LOR,CO.RNDA,CO.RNDD,CO.RNDM 
          EXT    CO.RNDS,CP.AFLS,CP.IFMT,CP.NFLS,FV.LGO,F.LGO,F.PB,F.REF
          EXT    IDPCHK,SYS=,WNB=,CO.LOM,NOM.FL 
          EXT    CO.OPT,CP.MXFL,MAX.FL,MEMERR,NOM.FLS,INT.FL
  
*         IN IDP
          EXT    IDP=,IDP=USY,UKT=FE,UKT=LNK
  
*         IN LABEL
          EXT    WIN
  
*         IN LIST 
          EXT    FIN.OL 
  
*         IN MAP
          EXT    FIN.MAP,FIN
  
*         IN PEM
          EXT    ANSI.SW
  
*         IN PUC
          EXT    ERRTYP,L.TABS,O.TABS,PUC,THRESH
  
*         IN QSKEL
          EXT    F.SKEL 
  
*         IN UTILITY
          EXT    RPV= 
 FCA      SPACE  4,8
**        FCA -  FINISHED WITH COMPASS ASSEMBLY.
* 
*         ENTRY  THE (1,0) HAS JUST BEEN RELOADED AFTER RETURNING FROM
*                *COMPASS*, AND THE INPUT FILE IS NOT FINISHED. 
* 
*         EXIT   TO PROGRAM UNIT CONTROLLER *PUC*.
* 
*         CALLS  FNL, GOI 
  
  
 FTN10    BSSENT 0
  
*         TURN ON REPRIEVE. 
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
          SA1    RA.SSW      SENSE SWITCH WORD
          LX1    59-5-6      GET SWITCH 6 
          MI     X1,INI1     IF SWITCH 6 ON 
 .TEST    ENDIF 
  
          RPVON              TURN ON REPRIEVE 
  
*         CHECK FOR IDP BREAK REQUEST.
* 
*         LINK *FRONT END* IDP USER KEYWORD TABLE.
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
 INI1     BSS    0
 #OS      IFNE   .OS,2
          SX6    =XUKT=FE    (X6) = FWA OF *FRONT END* IDP KEYWORD TBL
          SA6    =XUKT=LNK
          SX6    =YUSY=FE    (X6) = ADDR OF IDP SYMBOL SEARCH SUBR
          SA6    =XIDP=USY
          CALL   IDPCHK      CHECK FOR IDP REQUEST
          PL     B7,INI2     IF IDP NOT REQUESTED 
 FTN10    BREAK 
 #OS      ENDIF 
 .TEST    ENDIF 
  
*         INITIALIZE OVERLAY. 
  
 INI2     SA1    =XCP.IFMT
          MI     X1,=XPUC    IF EOR, LET PUC CLEAN UP...
  
          RJ     GOI         GLOBAL OVERLAY INITIALIZATION
          EQ     =XPUC       EXIT TO PROGRAM UNIT CONTROLLER... 
          SPACE  4,4
          LIST   -X          COMFGOI, COMFFEI, COMSEIS, COMFROR AND 
                             FA=SET ARE LISTED IN DECK INIT00.
  
*CALL     COMFGOI            GLOBAL OVERLAY INITIALIZATION (QCG)
  
*CALL     COMFFEI                  FRONT END INITIALIZATION 
  
*CALL     COMSEIS            DEFINE THE SK. DATA STRUCTURE
  
*CALL     COMFROR            RESET OPCODE OF ROUNDABLES 
  
          SPACE  4,10 
          LIST   D
          ENTRY  B=LWA10
 B=LWA10  END                MARK END OF OVERLAY FOR RPV
