*COMDECK  CCOMISC 
 SETCORE  CTEXT  CCOMISC - INITIALIZE SMALL CORE ( SETCORE ). 
  
          IF     -DEF,QUAL$,1 
          QUAL   COMCISC
*         COMMENT COPYRIGHT CONTROL DATA SYSTEMS, INC. 1994.
 ISC=     SPACE  3,8
***       ISC - INITIALIZE A BLOCK OF SCM TO A GIVEN VALUE
* 
* 
*         ENTRY  (X1) = BLOCK LENGTH
*                (X6) = VALUE TO SET
*                (A6) = BLOCK FWA (WORD 1 ALREADY STORED) 
* 
*         EXIT   (X6) = UNCHANGED 
*                (X7) = (X6)
*                (A6) = BLOCK LWA 
*                (B1) = 1 
* 
*         USES   X - 1, 2, 7
*                A - 6, 7 
*                B - 1
* 
*         CALLS  NONE 
  
  
 SETC2    SA7    A6+1 
          IX1    X1-X2
          SA6    A7+B1
          PL     X1,SETC2    IF ALL OF BLOCK NOT SET
  
 ISC=     PS                 ENTRY/EXIT 
  
          IFNE   TEST,0,2 
          SB1    X1+
          LE     B1,*+1S17   ABORT JOB IF LENGTH ERROR
  
          SX2    1
          NO
          BX7    -X1*X2      EXTRACT COMPLEMENT OF LSB
          SB1    X7          (B1) = 1 IF LENGTH EVEN, = 0 IF ODD
          SX1    X1-3        DECREMENT LENGTH 
          SA6    A6+B1       SET 2ND WORD IF LENGTH WAS EVEN
          LX2    1           (X2) = 2 
          SB1    1
          BX7    X6 
          PL     X1,SETC2    IF ALL OF BLOCK NOT SET
          EQ     ISC= 
  
          IF     -DEF,QUAL$,2 
          QUAL   *
 ISC=     EQU    /COMCISC/ISC=
  
          ENDX
