*COMDECK,FA=RWX 
          CTEXT  FA=RWX - REWIND FILE (FANCY) 
 RWX      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   FA=RWX 
  
  
**        FA=RWX - REWIND FILE (SUPPRESSED FOR SCRATCH FILES).
* 
*         SEQUENTIAL BINARY FILE -
*           REWINDS THE FILE, UNLESS THE HOLDING BUFFER HAS NOT 
*           OVERFLOWED AND THE COMPILER IS ASSEMBLED IN SYSTEM MODE.
* 
*         OTHER FILE TYPE - 
*           REWINDS THE FILE UNCONDITIONALLY. 
* 
* 
*         ENTRY  (X2) = PSEUDO-FET WORD 1 
*                (A2) = PSEUDO-FET ADDRESS
* 
*         EXIT   (X2) = PSEUDO-FET WORD 1 
*                (A2) = PSEUDO-FET ADDRESS
* 
*         USES   X - 1, 6, 7
*                A - 1, 6 
*                B - NONE 
* 
*         CALLS  REWINDM
  
  
 FA=RWX   JP     *+4S15      ** ENTRY/EXIT ** 
          PL     X2,RWX2     IF FILE HAS NO HOLDING BUFFER
          SA1    A2+I.FIRST 
          IX7    X2+X2       LEFT ADJUST SPILL FLAG 
          BX6    X1 
          SA6    A2+I.OUT    SET -OUT- = -FIRST-
  
          IFEQ   TEST,0,1 
          PL     X7,FA=RWX   IF HOLDING BUFFER HAS NOT SPILLED, EXIT
  
          SA6    A2+I.IN     SET -IN- = -FIRST- 
 RWX2     REWINDM   X2
          JP     FA=RWX      EXIT 
  
  
          IF     -DEF,QUAL$,2 
          QUAL   *
 FA=RWX   EQU    /FA=RWX/FA=RWX 
          ENDX
