*COMDECK,FA=RDC 
          CTEXT  FA=RDC - READ CODED LINE, -C- FORMAT 
 RDC      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   FA=RDC 
  
  
**        FA=RDC - READ ONE CODED LINE FROM FILE, IN -C- FORMAT.
* 
* 
*         ENTRY  (X2) = PSEUDO-FET WORD 1.
*                (A2) = PSEUDO-FET ADDRESS. 
*                (B1) = 1 
*                (B6) = WSA ADDRESS.
*                (B7) = WSA LENGTH (WORDS). 
* 
*         EXIT   (X1) = 0 FOR TRANSFER COMPLETE.
*                (X1) = -1 IF EOP/EOI DETECTED ON FILE. 
*                (X1) = (B6) IF EOS DETECTED ON FILE BEFORE TRANSFER
*                            WAS COMPLETED. 
*                (X2) = ADDRESS OF FIT FOR FILE.
*                (B1) = 1 
*                (B6) = ADDRESS PLUS ONE OF LAST WORD TRANSFERRED TO
*                            WORKING STORAGE AREA.
* 
*         USES   X - 1, 3, 4, 6, 7
*                A - 1, 3, 6, 7 
*                B - 2, 6 
* 
*         CALLS  FETCH, GETW, STORE 
  
  
 FA=RDC   JP     *+4S15      ** ENTRY/EXIT ** 
  
          IFNE   TEST,0,1 
          LE     B7,B0,*+4S15      IF LENGTH ERROR, ABORT JOB 
  
          SX3    B6          (X3) = WSA ADDRESS 
          SX4    B7          (X4) = WSA LENGTH
          GETW   X2,X3,X4,RDC2
          SB6    B6+X4       (B6) = LWA+1 OF TRANSFER 
          AX4    18D         (X4) = UNUSED BIT COUNT
          SA3    B6-B1       LAST WORD OF LINE
          MX6    1
          SB2    X4-59D 
          MX7    0
          AX4    X6,-B2 
          MX1    0           *TRANSFER COMPLETE* STATUS 
          BX6    X4*X3       DISCARD UNUSED BITS
          AX4    6
          SA6    A3          TERMINATE LAST WORD READ 
          NZ     X4,FA=RDC   IF AT LEAST 12-BIT LINE TERMINATOR, EXIT 
          SB6    B6+B1       INCREMENT LWA+1 OF TRANSFER
          SA7    A6+B1       TERMINATE LINE 
          JP     FA=RDC      EXIT 
  
*         HERE IF END-OF-DATA ENCOUNTERED.
  
 RDC2     JP     *+4S15      ** REC MGR SIMULATES -RJ- HERE IF E-O-D ** 
          FETCH  X2,FP,X3,X1
          SX3    X3-#EOS# 
          SB6    B6+X4       (B6) = LWA+1 OF TRANSFER 
          SX1    B6          TO RETURN *EOS* STATUS 
          ZR     X3,FA=RDC   IF EOS, EXIT 
          MX1    -1          RETURN EOP/EOI STATUS
          JP     FA=RDC      EXIT 
  
  
          IF     -DEF,QUAL$,2 
          QUAL   *
 FA=RDC   EQU    /FA=RDC/FA=RDC 
          ENDX
